Skip to content

Latest commit

 

History

History
71 lines (50 loc) · 2.08 KB

sample_358.md

File metadata and controls

71 lines (50 loc) · 2.08 KB

主页

检索默认假脱机目录(后台打印文件夹)名称

翻译:xinjie 2020.12.31

开始之前:

参考:


代码:

DO decl

LOCAL cPrinter, hPrinter, lnType, lcBuffer, lnBufsize
cPrinter = GetDefaultPrinter()
STORE 0 TO hPrinter, lnType, lnBufsize

IF OpenPrinter(cPrinter, @hPrinter, 0) <> 0
	lcBuffer = Repli(Chr(0), 250)
	= GetPrinterData(hPrinter, "DefaultSpoolDirectory",;
		@lnType, @lcBuffer, Len(lcBuffer), @lnBufsize)

	? "默认假脱机目录:", SUBSTR(lcBuffer, 1,lnBufsize-1)

	= ClosePrinter(hPrinter)
ENDIF
* 主程序结束

FUNCTION GetDefaultPrinter
	LOCAL lcBuffer
	lcBuffer = Repli(Chr(0), 120)

	* 检索打印机、打印机驱动程序和输出端口名
	DECLARE INTEGER GetProfileString IN kernel32;
		STRING lpApp, STRING lpKey, STRING lpDefault,;
		STRING @lpReturnedString, INTEGER nSize

	= GetProfileString("Windows", "Device", ",,,", @lcBuffer, Len(lcBuffer))
	lcBuffer = STRTRAN(lcBuffer, Chr(0), "")
RETURN SUBSTR(lcBuffer, 1, AT(",", lcBuffer)-1)

PROCEDURE decl
	DECLARE INTEGER GetPrinterData IN winspool.drv;
		INTEGER hPrinter, STRING pValueName, INTEGER @pType,;
		STRING @pData, LONG nSize, LONG @pcbNeeded

	DECLARE INTEGER OpenPrinter IN winspool.drv;
		STRING pPrinterName, INTEGER @phPrinter, INTEGER pDefault

	DECLARE INTEGER ClosePrinter IN winspool.drv INTEGER hPrinter  

函数列表:

ClosePrinter
GetPrinterData
GetProfileString
OpenPrinter

Comment:

可能存在某些原因更改打印假脱机目录(WIN10:后台打印文件夹),可以使用 SetPrinterData 函数或通过“开始-设置-打印机”命令手动完成此任务。