Skip to content

Latest commit

 

History

History
88 lines (62 loc) · 2.7 KB

sample_147.md

File metadata and controls

88 lines (62 loc) · 2.7 KB

主页

使用 Semaphore 对象只允许一个VFP应用实例运行

翻译:xinjie 2021.01.01

开始之前:

测试这个示例的最好方法是用下面的代码创建一个项目,并将其编译成可执行文件。无论你选择哪种方式:可执行文件、应用程序或其他VFP实例--这段代码都能正常工作。

参考:


代码:

#DEFINE WAIT_OBJECT_0     0
#DEFINE STATUS_TIMEOUT  258

#DEFINE STANDARD_RIGHTS_REQUIRED 0xf0000
#DEFINE SYNCHRONIZE              0x100000

*| STANDARD_RIGHTS_REQUIRED Or SYNCHRONIZE Or 3
#DEFINE SEMAPHORE_ALL_ACCESS     0x1f0003

DO decl

	LOCAL hSmp, lcSmp
	lcSmp = "TestSmp"
	
	* 试图打开一个名为TestSmp的 semaphore
	hSmp = OpenSemaphore (STANDARD_RIGHTS_REQUIRED, 0, lcSmp)

	IF hSmp = 0
	* 没有找到 Semaphore 对象
	* 创建新的 Semaphore 对象
		hSmp = CreateSemaphore (0, 1, 1, lcSmp)
		IF hSmp = 0
			= MessageB("不能创建所需的 Semaphore 对象。   " +;
			Chr(13)+ "错误代码: " +;
			LTRIM(STR(GetLastError())))
			RETURN
		ENDIF
		
		= MessageB("新的 Semaphore 对象已经被创建:   " + Chr(13) +;
			"name=" + lcSmp + ", handle=" + LTRIM(STR(hSmp)))

		* 在这里运行你的程序
		* ...
	ELSE
	* 这个名字的 Semaphore 对象已经存在,这意味着该进程已经在运行。
		= MessageB("进程已经在运行中。   ")
	ENDIF

	* 进程终止时,系统会自动关闭句柄,因此下行是多余的
	= CloseHandle(hSmp)

PROCEDURE  decl
	DECLARE INTEGER GetLastError IN kernel32

	DECLARE INTEGER CloseHandle IN kernel32 INTEGER hObject

	DECLARE INTEGER CreateSemaphore IN kernel32;
		INTEGER lcSmAttr, INTEGER lInitialCount,;
		INTEGER lMaximumCount, STRING lpName

	DECLARE INTEGER OpenSemaphore IN kernel32;
		INTEGER dwDesiredAccess,;
		INTEGER bInheritHandle, STRING lpName  

函数列表:

CloseHandle
CreateSemaphore
GetLastError
OpenSemaphore

备注:

使用了两个函数的组合--Create...和Open...。,Semaphore 对象并不是唯一适合这个任务的 。

同样也可以用Mutex对象(MutuallyExclusive),或者Event对象来完成。首先你要尝试打开命名的对象。如果它已经存在,那就意味着另一个VFP应用实例正在运行。否则你在这个实例中创建对象。