Skip to content

Latest commit

 

History

History
99 lines (74 loc) · 2.94 KB

sample_068.md

File metadata and controls

99 lines (74 loc) · 2.94 KB

主页

检索互联网连接的状态

翻译:xinjie 2021.01.11

请注意,本文件中包含一些与旧的news2news网站的链接,该网站目前无法使用。这些材料将在今后某个时候提供。

开始之前:

在Visual FoxPro中对文件传输协议进行编程

代码:

#DEFINE INTERNET_CONNECTION_MODEM        1
#DEFINE INTERNET_CONNECTION_LAN          2
#DEFINE INTERNET_CONNECTION_PROXY        4
#DEFINE INTERNET_CONNECTION_MODEM_BUSY   8
#DEFINE INTERNET_RAS_INSTALLED          16
#DEFINE INTERNET_CONNECTION_OFFLINE     32
#DEFINE INTERNET_CONNECTION_CONFIGURED  64

	DECLARE SHORT InternetGetConnectedState IN wininet.dll;
		INTEGER @lpdwFlags, INTEGER dwReserved

	DECLARE SHORT InternetGetConnectedStateEx IN wininet.dll;
    	INTEGER @lpdwFlags, STRING @lpszConnectionName,;
    	INTEGER dwNameLen, INTEGER dwReserved

	DO displayState
	DO displayStateEx
RETURN

PROCEDURE  displayState
	? "*** InternetGetConnectedState:"
	lpdwFlags = 0
	IF InternetGetConnectedState (@lpdwFlags, 0) = 1
		? "  返回的标志:       " +;
			LTRIM(STR(lpdwFlags))

		? "  调制解调器连接:     " +;
			_ok(lpdwFlags, INTERNET_CONNECTION_MODEM)

		? "  局域网连接:       " +;
			_ok(lpdwFlags, INTERNET_CONNECTION_LAN)

		? "  代理连接:     " +;
			_ok(lpdwFlags, INTERNET_CONNECTION_PROXY)

		? "  调制解调器忙:    " +;
			_ok(lpdwFlags, INTERNET_CONNECTION_MODEM_BUSY)

		? "  安装了RAS: " +;
			_ok(lpdwFlags, INTERNET_RAS_INSTALLED)

		? "  脱机连接:   " +;
			_ok(lpdwFlags, INTERNET_CONNECTION_OFFLINE)

		? "  已配置:        " +;
			_ok(lpdwFlags, INTERNET_CONNECTION_CONFIGURED)
	ELSE
		? "InternetGetConnectedState error"
	ENDIF
RETURN

PROCEDURE  displayStateEx
* 除返回连接名称外,与常规连接相同
	?
	? "*** InternetGetConnectedStateEx:"
	lpdwFlags = 0
	lcConnection = REPLI (Chr(0), 250)
	IF InternetGetConnectedStateEx (@lpdwFlags,;
		@lcConnection, Len(lcConnection), 0) = 1

		? "  返回的标志:       " + LTRIM(STR(lpdwFlags))
		? "  连接名: " +;
			SUBSTR (lcConnection, 1, AT(Chr(0), lcConnection)-1)
	ELSE
		? "InternetGetConnectedStateEx error"
	ENDIF
RETURN

FUNCTION  _ok (lnBase, lnValue)
RETURN  Iif(BitAnd(lnBase, lnValue)=lnValue, "Yes","No")  

函数列表:

InternetGetConnectedState
InternetGetConnectedStateEx

备注:

远程访问服务(RAS)使用Microsoft&reg 对计算机上的客户端应用程序提供远程访问功能。 Windows® 95或更高版本以及Windows NT® 3.5版和更高版本(包括Windows 2000)操作系统。