pytest/flake.nix at 7db658b673f5bf9fb8fe6e48c466f24ac4bc2acb · pytest-dev/pytest · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
{
  description = "Development environment for Pytest";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-25.11";
    nixpkgs-unstable.url = "github:NixOS/nixpkgs";
    systems.url = "github:nix-systems/default";
  };

  outputs = { self, nixpkgs, nixpkgs-unstable, systems }:
    let
      forAllSystems = nixpkgs.lib.genAttrs (import systems);
      mkPkgs = system: import nixpkgs {
        inherit system;
        overlays = [ self.overlays.newer-pre-commit ];
      };
    in
    {
      packages = forAllSystems (system:
        let
          pkgs = mkPkgs system;
        in
        {
          fhs-test-env = pkgs.buildFHSEnv {
            name = "fhs-test-env";
            targetPkgs = fhspkgs:
              let
                python313-with-tox = pkgs.python313.withPackages (ps: with ps; [
                  tox
                ]);
              in
              [
                python313-with-tox

                # other Pythons
                fhspkgs.python310
                fhspkgs.python311
                fhspkgs.python312
                fhspkgs.python314

                fhspkgs.bashInteractive
                fhspkgs.pre-commit

              ];
            runScript = "bash";
          };
        });

      devShells = forAllSystems (system:
        let
          pkgs = mkPkgs system;
        in
        {
          default = pkgs.mkShell {
            packages = [ self.packages.${system}.fhs-test-env ];
            shellHook = "exec fhs-test-env";
          };
        });

      overlays = {
        newer-pre-commit = final: prev: {
          pre-commit =
            let
              pkgs = import nixpkgs-unstable { inherit (final.stdenv.hostPlatform) system; };
            in
            pkgs.pre-commit;
        };
      };
    };
}