[SingleSource] Avoid race condition in symlink creation for forced opt vectorizer tests (#381)

Commit 6ac4455 added variants of the
vectorizer tests, built from the same source file. But each variant uses
the same reference output (e.g. `early-exit.reference_output`). A
symlink to this file is made in the build directory, and for parallel
builds we can get an error like:

```
CMake Error: failed to create symbolic link '/home/buildbot-worker/bbroot/clang-riscv-gauntlet/llvm-test-suite/build.rva23/SingleSource/UnitTests/Vectorizer/early-exit.reference_output': File exists
```

Essentially the same problem was fixed before in-tree in
a086e60. This patch implements a fix
along the same lines. llvm_singlesource now accepts a `DEST_SUFFIX`
which is plumbed through so that a unique symlink is created per test
variant.

A script like the following will reproduce the issue:

```
targets="
SingleSource/UnitTests/Vectorizer/early-exit
SingleSource/UnitTests/Vectorizer/tf-early-exit
SingleSource/UnitTests/Vectorizer/tfactivelanemask-early-exit
SingleSource/UnitTests/Vectorizer/ftic-early-exit
SingleSource/UnitTests/Vectorizer/tf-ftic-early-exit
SingleSource/UnitTests/Vectorizer/tfactivelanemask-ftic-early-exit
"

for i in $(seq 1 50); do
  echo "attempt $i"

  rm -f SingleSource/UnitTests/Vectorizer/early-exit.reference_output
  ninja -t clean $targets >/dev/null || exit 1
  if ! ninja -j32 $targets; then
    echo "reproduced: parallel build failed; look above for the create_symlink File exists error"
    exit 0
  fi
done

echo "did not reproduce"
exit 1
```

I made use of an LLM (GPT 5.4) to debug the failure, find an in-tree
example of the same issue being worked around, and to apply that pattern
here.

Author: asb

SingleSource/UnitTests/Vectorizer/CMakeLists.txt

@@ -1,6 +1,10 @@
 set(CMAKE_CXX_STANDARD 17)
 llvm_singlesource()
 
+function(llvm_vectorizer_variant prefix)
+  llvm_singlesource(PREFIX "${prefix}-" DEST_SUFFIX "-${prefix}")
+endfunction()
+
 # The VPlan-native path is specific to llvm.
 if ("${CMAKE_C_COMPILER_ID}" MATCHES "Clang")
   add_subdirectory(VPlanNativePath)
@@ -12,22 +16,22 @@ if ("${CMAKE_C_COMPILER_ID}" MATCHES "Clang")
     "-mllvm" "-prefer-predicate-over-epilogue=predicate-dont-vectorize"
     "-mllvm" "-force-tail-folding-style=data"
   )
-  llvm_singlesource(PREFIX "tfactivelanemask-")
+  llvm_vectorizer_variant("tfactivelanemask")
 
   # Add targets for all tests with forced tail folding using data without lane mask.
   set(CXXFLAGS ${BASE_CXXFLAGS})
   list(APPEND CXXFLAGS
     "-mllvm" "-prefer-predicate-over-epilogue=predicate-dont-vectorize"
     "-mllvm" "-force-tail-folding-style=data-without-lane-mask"
   )
-  llvm_singlesource(PREFIX "tf-")
+  llvm_vectorizer_variant("tf")
 
   # Add targets with instruction cost forced to 1.
   set(CXXFLAGS ${BASE_CXXFLAGS})
   list(APPEND CXXFLAGS
     "-mllvm" "-force-target-instruction-cost=1"
   )
-  llvm_singlesource(PREFIX "ftic-")
+  llvm_vectorizer_variant("ftic")
 
   # Add targets with instruction cost forced to 1 and forced tail-folding.
   set(CXXFLAGS ${BASE_CXXFLAGS})
@@ -36,7 +40,7 @@ if ("${CMAKE_C_COMPILER_ID}" MATCHES "Clang")
     "-mllvm" "-prefer-predicate-over-epilogue=predicate-dont-vectorize"
     "-mllvm" "-force-tail-folding-style=data"
   )
-  llvm_singlesource(PREFIX "tfactivelanemask-ftic-")
+  llvm_vectorizer_variant("tfactivelanemask-ftic")
 
   # Add targets with instruction cost forced to 1 and forced tail-folding without lane mask.
   set(CXXFLAGS ${BASE_CXXFLAGS})
@@ -45,7 +49,7 @@ if ("${CMAKE_C_COMPILER_ID}" MATCHES "Clang")
     "-mllvm" "-prefer-predicate-over-epilogue=predicate-dont-vectorize"
     "-mllvm" "-force-tail-folding-style=data-without-lane-mask"
   )
-  llvm_singlesource(PREFIX "tf-ftic-")
+  llvm_vectorizer_variant("tf-ftic")
 
   set(CXXFLAGS ${BASE_CXXFLAGS})
 endif()

cmake/modules/SingleMultiSource.cmake

@@ -29,7 +29,7 @@ include(TestSuite)
 # Configure the current directory as a SingleSource subdirectory - i.e. every
 # C/C++/Fortran file is treated as its own test.
 function(llvm_singlesource)
-  cmake_parse_arguments(_LSARG "" "PREFIX" "" ${ARGN})
+  cmake_parse_arguments(_LSARG "" "DEST_SUFFIX;PREFIX" "" ${ARGN})
   if(DEFINED Source)
     set(sources ${Source})
   else()
@@ -42,7 +42,11 @@ function(llvm_singlesource)
     set(_target ${_LSARG_PREFIX}${name})
     llvm_test_executable_no_test(${_target} ${source})
     set_property(TARGET ${_target} PROPERTY TEST_NAME ${name})
-    llvm_test_traditional(${_target})
+    set(DEST_SUFFIX_ARGS)
+    if(_LSARG_DEST_SUFFIX)
+      list(APPEND DEST_SUFFIX_ARGS DEST_SUFFIX ${_LSARG_DEST_SUFFIX})
+    endif()
+    llvm_test_traditional(${_target} ${DEST_SUFFIX_ARGS})
     llvm_add_test_for_target(${_target})
   endforeach()
 endfunction()
@@ -79,15 +83,21 @@ endmacro()
 # HASH_PROGRAM_OUTPUT, etc.
 # Create llvm_test_run() and llvm_test_verify() invocation for that.
 function(llvm_test_traditional target)
+  cmake_parse_arguments(_LTTARGS "" "DEST_SUFFIX" "" ${ARGN})
   get_property(name TARGET ${target} PROPERTY TEST_NAME)
   if(NOT name)
     set(name ${target})
   endif()
+  set(DEST_SUFFIX_ARGS)
+  if(_LTTARGS_DEST_SUFFIX)
+    list(APPEND DEST_SUFFIX_ARGS DEST_SUFFIX ${_LTTARGS_DEST_SUFFIX})
+  endif()
 
   # Find the reference input
   if(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/${name}.reference_input)
-    list(APPEND RUN_OPTIONS < %S/${name}.reference_input)
-    llvm_test_data(${target} ${name}.reference_input)
+    list(APPEND RUN_OPTIONS < %S/${name}.reference_input${_LTTARGS_DEST_SUFFIX})
+    llvm_test_data(${target} ${DEST_SUFFIX_ARGS}
+                   ${name}.reference_input)
   endif()
 
   # Always run in the same directory as the executable
@@ -135,8 +145,9 @@ function(llvm_test_traditional target)
     if(FP_IGNOREWHITESPACE)
       set(DIFFPROG "${DIFFPROG} -i")
     endif()
-    llvm_test_verify(${DIFFPROG} %o %S/${REFERENCE_OUTPUT})
-    llvm_test_data(${target} ${REFERENCE_OUTPUT})
+    llvm_test_verify(${DIFFPROG} %o %S/${REFERENCE_OUTPUT}${_LTTARGS_DEST_SUFFIX})
+    llvm_test_data(${target} ${DEST_SUFFIX_ARGS}
+                   ${REFERENCE_OUTPUT})
   endif()
   set(TESTSCRIPT "${TESTSCRIPT}" PARENT_SCOPE)
 endfunction()