CLJS-2593: Integration test suite for cljs.main

Author: mfikes

.travis.yml

@@ -1,5 +1,8 @@
 dist: trusty
 
+git:
+  depth: 500
+
 language: node_js
 
 node_js:
@@ -14,6 +17,7 @@ before_install:
 
 before_script:
   - script/bootstrap
+  - script/uberjar
   - mkdir -p builds/out-adv
   - bin/cljsc src/test/cljs "{:optimizations :advanced
                               :output-wrapper true
@@ -53,3 +57,9 @@ script:
   - grep '0 failures, 0 errors.' test-out.txt
   - script/test-self-parity | tee test-out.txt
   - grep '0 failures, 0 errors.' test-out.txt
+  - script/test-cli node | tee test-out.txt
+  - grep '0 failures, 0 errors.' test-out.txt
+  - script/test-cli nashorn | tee test-out.txt
+  - grep '0 failures, 0 errors.' test-out.txt
+  - script/test-cli rhino | tee test-out.txt
+  - grep '0 failures, 0 errors.' test-out.txt

script/test-cli

@@ -0,0 +1,8 @@
+#!/bin/sh
+
+if [ ! -f target/cljs.jar ]; then
+  echo "Run script/uberjar first"
+  exit 1
+fi
+
+java -cp target/cljs.jar:src/test/cljs_cli clojure.main -m cljs-cli.test-runner "$@"

src/test/cljs_cli/cljs_cli/test.clj

@@ -0,0 +1,62 @@
+(ns cljs-cli.test
+  (:require
+   [clojure.test :refer [deftest]]
+   [clojure.java.io :as io]
+   [clojure.java.shell :as shell :refer [with-sh-dir]]
+   [cljs-cli.util :refer [cljs-main output-is with-sources with-post-condition with-repl-env-filter]]))
+
+(deftest eval-test
+  (-> (cljs-main "-e" 3 "-e" nil "-e" 4)
+    (output-is 3 4)))
+
+(deftest init-test
+  (with-sources {"src/foo/core.cljs"
+                 "(ns foo.core) (def x 3)"}
+    (-> (cljs-main "-i" "src/foo/core.cljs" "-e" 'foo.core/x)
+      (output-is 3))))
+
+(deftest main-test
+  (with-sources {"src/foo/core.cljs"
+                 "(ns foo.core) (defn -main [] (prn :hi))"}
+    (-> (cljs-main "-m" "foo.core")
+      (output-is :hi))))
+
+(deftest command-line-args-test
+  (with-sources {"src/foo/core.cljs"
+                 "(ns foo.core) (prn *command-line-args*)"}
+    (-> (cljs-main "src/foo/core.cljs" "alpha" "beta" "gamma")
+      (output-is (pr-str '("alpha" "beta" "gamma"))))))
+
+(deftest command-line-args-empty-test
+  (with-sources {"src/foo/core.cljs"
+                 "(ns foo.core) (prn *command-line-args*)"}
+    (-> (cljs-main "src/foo/core.cljs")
+      (output-is nil))))
+
+(deftest initial-ns-test
+  (-> (cljs-main "-e" "::foo")
+    (output-is ":cljs.user/foo")))
+
+(deftest source-test
+  (with-sources {"src/foo/core.cljs"
+                 "(ns foo.core) (prn :hi)"}
+    (-> (cljs-main "src/foo/core.cljs")
+      (output-is :hi))))
+
+(deftest compile-test
+  (with-sources {"src/foo/core.cljs"
+                 "(ns foo.core) (defn -main [] (prn :hi))"}
+    (with-post-condition (fn [dir] (.exists (io/file dir "out" "main.js")))
+      (-> (cljs-main "-o" "out/main.js" "-c" "foo.core")
+        (output-is)))))
+
+(deftest run-optimized-node-test
+  (with-repl-env-filter #{"node"}
+    (with-sources {"src/foo/core.cljs"
+                   "(ns foo.core) (prn :hello-from-node)"}
+      (with-post-condition (fn [dir]
+                             (= {:exit 0, :out ":hello-from-node\n", :err ""}
+                               (with-sh-dir dir
+                                 (shell/sh "node" (str (io/file dir "out" "main.js"))))))
+        (-> (cljs-main "-t" "node" "-o" "out/main.js" "-O" "advanced" "-c" "foo.core")
+          (output-is))))))

src/test/cljs_cli/cljs_cli/test_runner.clj

@@ -0,0 +1,12 @@
+(ns cljs-cli.test-runner
+  (:require
+   [cljs-cli.test]
+   [cljs-cli.util]))
+
+(defn -main [& args]
+  (try
+    (binding [cljs-cli.util/*repl-env* (or (first args) "nashorn")
+              cljs-cli.util/*repl-opts* (second args)]
+      (clojure.test/run-tests 'cljs-cli.test))
+    (finally
+      (shutdown-agents))))

src/test/cljs_cli/cljs_cli/util.clj

@@ -0,0 +1,93 @@
+(ns cljs-cli.util
+  (:require
+   [clojure.string :as string]
+   [clojure.java.io :as io]
+   [clojure.java.shell :as shell]
+   [clojure.test :refer [is]])
+  (:import
+   (java.io File)
+   (java.nio.file Files CopyOption)
+   (java.nio.file.attribute FileAttribute)))
+
+(def ^:dynamic *repl-env* "nashorn")
+(def ^:dynamic *repl-env-filter* (constantly true))
+(def ^:dynamic *repl-opts* nil)
+(def ^:dynamic *sources* nil)
+(def ^:dynamic *post-condition* nil)
+
+(defmacro with-sources
+  [sources & body]
+  `(binding [*sources* ~sources]
+     ~@body))
+
+(defmacro with-post-condition
+  [post-condition & body]
+  `(binding [*post-condition* ~post-condition]
+     ~@body))
+
+(defmacro with-repl-env-filter
+  [repl-env-filter & body]
+  `(binding [*repl-env-filter* ~repl-env-filter]
+     ~@body))
+
+(defn- ^File make-temp-dir []
+  (.toFile (Files/createTempDirectory "cljs-cli-test" (make-array FileAttribute 0))))
+
+(defn- delete-recursively [fname]
+  (doseq [f (reverse (file-seq (io/file fname)))]
+    (io/delete-file f)))
+
+(defn- copy-uberjar [^File dest]
+  (Files/copy (.toPath (io/file "target/cljs.jar")) (.toPath (io/file dest "cljs.jar")) (make-array CopyOption 0)))
+
+(defn- write-sources [temp-dir]
+  (let [qualified #(io/file temp-dir %)]
+    (run! #(io/make-parents (qualified %)) (keys *sources*))
+    (run! (fn [[file source]]
+            (spit (qualified file) source))
+      *sources*)))
+
+(defn- run-in-temp-dir [args]
+  (let [temp-dir (make-temp-dir)]
+    (try
+      (write-sources temp-dir)
+      (copy-uberjar temp-dir)
+      (let [result (shell/with-sh-dir temp-dir
+                     #_(apply println "running:" args)
+                     (apply shell/sh args))]
+        (when *post-condition*
+          (is (*post-condition* temp-dir)))
+        result)
+      (finally
+        (delete-recursively temp-dir)))))
+
+(defn form-cp []
+  (string/join File/pathSeparator ["cljs.jar" "src"]))
+
+(defn cljs-main [& args]
+  (if (*repl-env-filter* *repl-env*)
+    (let [command-line-args (map str args)]
+      (run-in-temp-dir
+        (keep (fn [arg]
+                (when arg
+                  (str arg)))
+          (into ["java" "-cp" (form-cp) "cljs.main"
+                 "-re" *repl-env*
+                 (when *repl-opts* "-ro") (when *repl-opts* *repl-opts*)]
+            command-line-args))))
+    {:exit 0 :out "" :err ""}))
+
+(def ^:private expected-browser-err
+  "Compiling client js ...\nServing HTTP on localhost port 9000\nListening for browser REPL connect ...\n")
+
+(defn- maybe-print-result-err [{:keys [err]}]
+  (when (and (not (empty? err))
+             (not (= expected-browser-err err)))
+    (binding [*out* *err*]
+      (println err))))
+
+(defn output-is [result & expected-lines]
+  (is (zero? (:exit result)))
+  (maybe-print-result-err result)
+  (is (= (apply str (map print-str (interleave expected-lines (repeat "\n"))))
+        (:out result))))