CLJS-2819: Warn on non-dynamic earmuffed vars

Author: mfikes

src/main/clojure/cljs/analyzer.cljc

@@ -153,6 +153,7 @@
    :single-segment-namespace true
    :munged-namespace true
    :ns-var-clash true
+   :non-dynamic-earmuffed-var true
    :extend-type-invalid-method-shape true
    :unsupported-js-module-type true
    :unsupported-preprocess-value true
@@ -467,6 +468,11 @@
   [warning-type {:keys [ns var] :as info}]
   (str "Namespace " ns " clashes with var " var))
 
+(defmethod error-message :non-dynamic-earmuffed-var
+  [warning-type {:keys [var] :as info}]
+  (str var " not declared dynamic and thus is not dynamically rebindable, but its name "
+    "suggests otherwise. Please either indicate ^:dynamic " var " or change the name"))
+
 (defmethod error-message :extend-type-invalid-method-shape
   [warning-type {:keys [protocol method] :as info}]
   (str "Bad extend-type method shape for protocol " protocol " method " method
@@ -1602,6 +1608,18 @@
     :set    (into #{} (map const-expr->constant-value (:items e)))
     :vector (into [] (map const-expr->constant-value (:items e)))))
 
+(defn- earmuffed? [sym]
+  (let [s (name sym)]
+    (and (> (count s) 2)
+         (string/starts-with? s "*")
+         (string/ends-with? s "*"))))
+
+(defn- core-ns? [ns-sym]
+  (let [s (name ns-sym)]
+    (and (not= 'cljs.user ns-sym)
+         (or (string/starts-with? s "cljs.")
+             (string/starts-with? s "clojure.")))))
+
 (defmethod parse 'def
   [op env form _ _]
   (when (> (count form) 4)
@@ -1639,6 +1657,11 @@
     (when-some [doc (:doc args)]
       (when-not (string? doc)
         (throw (error env "Too many arguments to def"))))
+    (when (and (not dynamic)
+               (earmuffed? sym)
+               (not (core-ns? ns-name)))
+      (warning :non-dynamic-earmuffed-var env
+        {:var (str sym)}))
     (when-some [v (get-in @env/*compiler* [::namespaces ns-name :defs sym])]
       (when (and (not *allow-redef*)
                  (not (:declared v))

src/test/clojure/cljs/analyzer_tests.clj

@@ -1737,3 +1737,10 @@
   (is (= "global$module$react" (a/munge-global-export 'react)))
   (is (= "global$module$_CIRCA_material_ui$core$styles" (a/munge-global-export "@material-ui/core/styles")))
   (is (= "node$module$_CIRCA_material_ui$core$styles" (ana/munge-node-lib "@material-ui/core/styles"))))
+
+(deftest test-cljs-2819
+  (let [ws (atom [])]
+    (a/with-warning-handlers [(collecting-warning-handler ws)]
+      (a/analyze ns-env
+        '(def *foo* 1)))
+    (is (string/starts-with? (first @ws) "*foo* not declared dynamic and thus"))))