CLJS-2660: Add cljs.core/eval which, delegates to an overridable *eval*

Author: mfikes

src/main/cljs/cljs/core.cljs

@@ -11510,3 +11510,17 @@ reduces them without incurring seq initialization"
           (.println (.-error system) (.join (into-array args) "")))))))
 
 (maybe-enable-print!)
+
+(defonce
+  ^{:doc "Runtime environments may provide a way to evaluate ClojureScript
+  forms. Whatever function *eval* is bound to will be passed any forms which
+  should be evaluated." :dynamic true}
+  *eval*
+  (fn [_]
+    (throw (ex-info "cljs.core/*eval* not bound" {}))))
+
+(defn eval
+  "Evaluates the form data structure (not text!) and returns the result.
+  Delegates to cljs.core/*eval*."
+  [form]
+  (*eval* form))

src/main/cljs/cljs/js.cljs

@@ -7,7 +7,7 @@
 ;   You must not remove this notice, or any other, from this software.
 
 (ns cljs.js
-  (:refer-clojure :exclude [require])
+  (:refer-clojure :exclude [require eval])
   (:require-macros [cljs.js :refer [dump-core]]
                    [cljs.env.macros :as env])
   (:require [clojure.string :as string]
@@ -786,10 +786,13 @@
 ;; -----------------------------------------------------------------------------
 ;; Eval
 
+(declare clear-fns!)
+
 (defn- eval* [bound-vars form opts cb]
   (let [the-ns     (or (:ns opts) 'cljs.user)
         bound-vars (cond-> (merge bound-vars {:*cljs-ns* the-ns})
                      (:source-map opts) (assoc :*sm-data* (sm-data)))]
+    (clear-fns!)
     (binding [env/*compiler*         (:*compiler* bound-vars)
               *eval-fn*              (:*eval-fn* bound-vars)
               ana/*cljs-ns*          (:*cljs-ns* bound-vars)
@@ -1037,6 +1040,7 @@
                      (:source-map opts) (assoc :*sm-data* (sm-data)))
         aname      (cond-> name (:macros-ns opts) ana/macro-ns-name)]
     (when (:verbose opts) (debug-prn "Evaluating" name))
+    (clear-fns!)
     (trampoline
      (fn compile-loop [ns]
        (binding [env/*compiler*         (:*compiler* bound-vars)
@@ -1193,6 +1197,61 @@
       :*eval-fn*      (or (:eval opts) *eval-fn*)}
      source name opts cb)))
 
+;;; Support for cljs.core/eval
+
+;; The following volatiles and fns set up a scheme to
+;; emit function values into JavaScript as numeric
+;; references that are looked up. Needed to implement eval.
+
+(defonce ^:private fn-index (volatile! 0))
+(defonce ^:private fn-refs (volatile! {}))
+
+(defn- clear-fns!
+  "Clears saved functions."
+  []
+  (vreset! fn-refs {}))
+
+(defn- put-fn
+  "Saves a function, returning a numeric representation."
+  [f]
+  (let [n (vswap! fn-index inc)]
+    (vswap! fn-refs assoc n f)
+    n))
+
+(defn- get-fn
+  "Gets a function, given its numeric representation."
+  [n]
+  (get @fn-refs n))
+
+(defn- emit-fn [f]
+  (print "cljs.js.get_fn(" (put-fn f) ")"))
+
+(defmethod comp/emit-constant js/Function
+  [f]
+  (emit-fn f))
+
+(defmethod comp/emit-constant cljs.core/Var
+  [f]
+  (emit-fn f))
+
+(defn- eval-impl
+  ([form]
+   (eval-impl form (.-name *ns*)))
+  ([form ns]
+   (let [result (atom nil)]
+     (let [st env/*compiler*]
+       (eval st form
+         {:ns            ns
+          :context       :expr
+          :def-emits-var true}
+         (fn [{:keys [value error]}]
+           (if error
+             (throw error)
+             (reset! result value)))))
+     @result)))
+
+(set! *eval* eval-impl)
+
 (comment
   (require '[cljs.js :as cljs]
            '[cljs.analyzer :as ana])

src/test/cljs/cljs/eval_test.cljs

@@ -0,0 +1,26 @@
+(ns cljs.eval-test
+  (:require [cljs.test :refer [deftest is]]))
+
+;;; This test namespace should only be loaded by environments that set up cljs.core/*eval*
+
+(def addition-list-1 (list + 1 2))
+(def addition-list-2 (list + 1 'a))
+(def addition-list-3 (list (fn [a b] (+ a b)) 1 2))
+(defn square [x] (* x x))
+(defn cube [x] (* x x x))
+
+(deftest test-eval
+  (is (== 1 (eval 1)))
+  (is (== 3 (eval '(+ 1 2))))
+  (is (== 17 (eval '(let [a 10] (+ 3 4 a)))))
+  (is (= 'a (:name (meta (eval '(def a 3))))))
+  (is (== 3 (eval 'a)))
+  (is (== 3 (eval addition-list-1)))
+  (is (== 4 (eval addition-list-2)))
+  (is (== 13 (eval (concat addition-list-1 [10]))))
+  (is (= 'lucky-number (:name (meta (eval (list 'def 'lucky-number (concat addition-list-1 [20])))))))
+  (is (== 23 (eval 'lucky-number)))
+  (is (== 64 ((eval (list comp square cube)) 2)))
+  (is (== 5 ((eval (eval +)) 2 3)))
+  (is (== 3 (eval addition-list-3)))
+  (is (== 4 (eval (list #'inc 3)))))

src/test/self/self_parity/test.cljs

@@ -258,73 +258,6 @@
         (print "caused by: ")
         (recur cause)))))
 
-;; The following volatiles and fns set up a scheme to
-;; emit function values into JavaScript as numeric
-;; references that are looked up. Needed to implement eval.
-
-(defonce ^:private fn-index (volatile! 0))
-(defonce ^:private fn-refs (volatile! {}))
-
-(defn- put-fn
-  "Saves a function, returning a numeric representation."
-  [f]
-  (let [n (vswap! fn-index inc)]
-    (vswap! fn-refs assoc n f)
-    n))
-
-(defn- get-fn
-  "Gets a function, given its numeric representation."
-  [n]
-  (get @fn-refs n))
-
-(defn- emit-fn [f]
-  (print "self_parity.test.get_fn(" (put-fn f) ")"))
-
-(defmethod comp/emit-constant js/Function
-  [f]
-  (emit-fn f))
-
-(defmethod comp/emit-constant cljs.core/Var
-  [f]
-  (emit-fn f))
-
-;; Inject an implementation of eval into needed macros namespaces
-
-(defn- eval
-  ([form]
-   (eval form (.-name *ns*)))
-  ([form ns]
-   (let [result (atom nil)]
-     (cljs/eval st form
-       {:ns            ns
-        :context       :expr
-        :def-emits-var true}
-       (fn [{:keys [value error]}]
-         (if error
-           (handle-error error (:source-maps @st))
-           (reset! result value))))
-     @result)))
-
-(defn- intern
-  ([ns name]
-   (when-let [the-ns (find-ns (cond-> ns (instance? Namespace ns) ns-name))]
-     (eval `(def ~name) (ns-name the-ns))))
-  ([ns name val]
-   (when-let [the-ns (find-ns (cond-> ns (instance? Namespace ns) ns-name))]
-     (eval `(def ~name ~val) (ns-name the-ns)))))
-
-(defn- inject-eval
-  [target-ns]
-  (intern target-ns 'eval eval))
-
-(defn- setup-eval []
-  (eval-form st 'cljs.user
-    '(require-macros 'cljs.spec.test.alpha)
-    (fn [{:keys [value error]}]
-      (if error
-        (handle-error error (:source-maps @st))
-        (inject-eval 'cljs.spec.test.alpha$macros)))))
-
 ;; Test suite runner
 
 (defn run-tests
@@ -336,6 +269,7 @@
   (eval-form st 'cljs.user
     '(ns parity.core
        (:require [cljs.test :refer-macros [run-tests]]
+                 [cljs.eval-test]
                  [cljs.primitives-test]
                  [cljs.destructuring-test]
                  [cljs.new-new-test]
@@ -377,6 +311,7 @@
         (handle-error error (:source-maps @st))
         (eval-form st 'parity.core
           '(run-tests
+             'cljs.eval-test
              'cljs.primitives-test
              'cljs.destructuring-test
              'cljs.new-new-test
@@ -419,7 +354,6 @@
 
 (defn -main [& args]
   (init-runtime)
-  (setup-eval)
   (run-tests))
 
 (set! *main-cli-fn* -main)