CLJS-2678: Infer-externs doesn't work for JS modules using global-exports

Author: dnolen

src/main/clojure/cljs/analyzer.cljc

@@ -976,8 +976,13 @@
 
 (defmethod resolve* :global
   [sym full-ns current-ns]
-  {:name (symbol (str current-ns) (str (munge-global-export full-ns) "." (name sym)))
-   :ns current-ns})
+  (let [pre (into '[Object] (->> (string/split (name sym) #"\.") (map symbol) vec))]
+    (when-not (has-extern? pre)
+      (swap! env/*compiler* update-in
+        (into [::namespaces current-ns :externs] pre) merge {}))
+    {:name (symbol (str current-ns) (str (munge-global-export full-ns) "." (name sym)))
+     :ns current-ns
+     :tag (with-meta 'js {:prefix pre})}))
 
 (defmethod resolve* :default
   [sym full-ns current-ns]

src/main/clojure/cljs/env.cljc

@@ -43,21 +43,23 @@ state that is accessed/maintained by many different components."}
 ;; implementation-dependent data.
 (def ^:dynamic *compiler* nil)
 
+(defn default-compiler-env* [options]
+  (merge
+    {:cljs.analyzer/namespaces {'cljs.user {:name 'cljs.user}}
+     :cljs.analyzer/constant-table {}
+     :cljs.analyzer/data-readers {}
+     :cljs.analyzer/externs #?(:clj  (when (:infer-externs options)
+                                       (externs/externs-map (:externs-sources options)))
+                               :cljs nil)
+     :options options}
+    #?@(:clj [(when (= (:target options) :nodejs)
+                {:node-module-index deps/native-node-modules})
+              {:js-dependency-index (deps/js-dependency-index options)}])))
+
 (defn default-compiler-env
   ([] (default-compiler-env {}))
   ([options]
-   (atom
-     (merge
-       {:cljs.analyzer/namespaces {'cljs.user {:name 'cljs.user}}
-        :cljs.analyzer/constant-table {}
-        :cljs.analyzer/data-readers {}
-        :cljs.analyzer/externs #?(:clj  (when (:infer-externs options)
-                                          (externs/externs-map (:externs-sources options)))
-                                  :cljs nil)
-        :options options}
-       #?@(:clj [(when (= (:target options) :nodejs)
-                   {:node-module-index deps/native-node-modules})
-                 {:js-dependency-index (deps/js-dependency-index options)}])))))
+   (atom (default-compiler-env* options))))
 
 #?(:clj
    (defmacro with-compiler-env

src/test/clojure/cljs/analyzer_tests.clj

@@ -862,14 +862,17 @@
    "goog.isArrayLike;" "Java.type;" "Object.out;" "Object.out.println;"
    "Object.error;" "Object.error.println;"])
 
-(defn infer-test-helper [{:keys [forms externs warnings warn with-core? opts]}]
-  (let [test-cenv (if with-core?
-                    (env/default-compiler-env
-                      (closure/add-externs-sources (merge {:infer-externs true} opts)))
-                    (atom
-                      {::a/externs
-                       (externs/externs-map
-                         (closure/load-externs {:externs (or externs [])}))}))
+(defn infer-test-helper
+  [{:keys [forms externs warnings warn js-dependency-index with-core? opts]}]
+  (let [test-cenv (atom
+                    (cond->
+                      (if with-core?
+                        (env/default-compiler-env*
+                          (closure/add-externs-sources (merge {:infer-externs true} opts)))
+                        {::a/externs
+                         (externs/externs-map
+                           (closure/load-externs {:externs (or externs [])}))})
+                      js-dependency-index (assoc :js-dependency-index js-dependency-index)))
         wrap      (if with-core?
                     #(comp/with-core-cljs nil %)
                     #(do (%)))]
@@ -1052,3 +1055,14 @@
     (not (string/includes? res "COMPILED"))
     (not (string/includes? res "goog"))
     (is (zero? (count @ws)))))
+
+(deftest test-cljs-2678-global-exports-infer
+  (let [ws  (atom [])
+        res (infer-test-helper
+              {:js-dependency-index {"react" {:global-exports '{react React}}}
+               :forms '[(ns foo.core
+                          (:require [react :as react]))
+                        (.log js/console react/Component)]
+               :warnings ws
+               :warn false})]
+    (is (= "Object.Component;\n" res))))