CLJS-3346: :as-alias (#119)

Implement `:as-alias` support as simple structural pass on the ns form EDN. All `:as-alias` are collected, and the ns libspecs are returned with `:as-alias` elided. If a lib spec has *only* `:as-alias` it is *removed* entirely. This is possible since `:as-alias` does not load.

The structural pass approach means further alterations to the analyzer or compiler are not needed. This aligns w/ the purpose of `:as-alias`, as it is primarily about feeding the reader.

One interesting thing to note is that ClojureScript has two difference namespaces - one for defs and one for macros and they may in fact collide. Since `:as-alias` is only about the reader - collisions are not allowed across defs and macros. That is, if a `:require-macros` libspec declares an `:as-alias` it cannot be reused by a `:require` libspec.

* change analyzer `ns` and `ns*` to support `:as-alias`
* change ns merging to deep merge `:as-aliases` 
* change `form-seq` reader helper to include `:as-aliases` from the current namespace
* change REPL reader to include `:as-aliases` from the current namespace

Author: swannodette

src/main/clojure/cljs/analyzer.cljc

@@ -14,6 +14,7 @@
                                      no-warn with-warning-handlers wrapping-errors]]
              [cljs.env.macros :refer [ensure]]))
   #?(:clj  (:require [cljs.analyzer.impl :as impl]
+                     [cljs.analyzer.impl.namespaces :as nses]
                      [cljs.analyzer.passes.and-or :as and-or]
                      [cljs.env :as env :refer [ensure]]
                      [cljs.externs :as externs]
@@ -27,6 +28,7 @@
                      [clojure.tools.reader :as reader]
                      [clojure.tools.reader.reader-types :as readers])
      :cljs (:require [cljs.analyzer.impl :as impl]
+                     [cljs.analyzer.impl.namespaces :as nses]
                      [cljs.analyzer.passes.and-or :as and-or]
                      [cljs.env :as env]
                      [cljs.reader :as edn]
@@ -3101,7 +3103,7 @@
   (if (pos? (count old))
     (let [deep-merge-keys
           [:use-macros :require-macros :rename-macros
-           :uses :requires :renames :imports]]
+           :uses :requires :renames :imports :as-aliases]]
       #?(:clj
          (when *check-alias-dupes*
            (check-duplicate-aliases env old new)))
@@ -3141,13 +3143,15 @@
                          #?(:clj  (rewrite-cljs-aliases
                                     (if metadata (next args) args))
                             :cljs (if (some? metadata) (next args) args)))
+          {:keys [as-aliases] args :libspecs} (nses/elide-aliases-from-ns-specs args)
           name         (vary-meta name merge metadata)
           {excludes :excludes core-renames :renames} (parse-ns-excludes env args)
           core-renames (reduce (fn [m [original renamed]]
                                  (assoc m renamed (symbol "cljs.core" (str original))))
                          {} core-renames)
           deps         (atom [])
-          aliases      (atom {:fns {} :macros {}})
+          ;; as-aliases can only be used *once* because they are about the reader
+          aliases      (atom {:fns as-aliases :macros as-aliases})
           spec-parsers {:require        (partial parse-require-spec env false deps aliases)
                         :require-macros (partial parse-require-spec env true deps aliases)
                         :use            (comp (partial parse-require-spec env false deps aliases)
@@ -3196,7 +3200,8 @@
                               spec-map)) [require-macros use-macros])])]
       (set! *cljs-ns* name)
       (let [ns-info
-            {:name           name
+            {:as-aliases     as-aliases
+             :name           name
              :doc            (or docstring mdocstr)
              :excludes       excludes
              :use-macros     use-macros
@@ -3239,12 +3244,14 @@
                        #?(:clj  (list (process-rewrite-form
                                         specs))
                           :cljs (list specs)))
+        {:keys [as-aliases] args :libspecs} (nses/elide-aliases-from-ns-specs args)
         {excludes :excludes core-renames :renames} (parse-ns-excludes env args)
         core-renames (reduce (fn [m [original renamed]]
                                (assoc m renamed (symbol "cljs.core" (str original))))
                        {} core-renames)
         deps         (atom [])
-        aliases      (atom {:fns {} :macros {}})
+        ;; as-aliases can only be used *once* because they are about the reader
+        aliases      (atom {:fns as-aliases :macros as-aliases})
         spec-parsers {:require        (partial parse-require-spec env false deps aliases)
                       :require-macros (partial parse-require-spec env true deps aliases)
                       :use            (comp (partial parse-require-spec env false deps aliases)
@@ -3275,7 +3282,8 @@
           {} (remove (fn [[r]] (= r :refer-clojure)) args))]
     (set! *cljs-ns* name)
     (let [require-info
-          {:name           name
+          {:as-aliases     as-aliases
+           :name           name
            :excludes       excludes
            :use-macros     use-macros
            :require-macros require-macros
@@ -4324,7 +4332,7 @@
                                      reader/*data-readers* data-readers
                                      reader/*alias-map*
                                      (apply merge
-                                       ((juxt :requires :require-macros)
+                                       ((juxt :requires :require-macros :as-aliases)
                                          (get-namespace *cljs-ns*)))
                                      reader/resolve-symbol resolve-symbol]
                              (reader/read opts pbr))]

src/main/clojure/cljs/analyzer/impl/namespaces.cljc

@@ -0,0 +1,68 @@
+;; Copyright (c) Rich Hickey. All rights reserved.
+;; The use and distribution terms for this software are covered by the
+;; Eclipse Public License 1.0 (http://opensource.org/licenses/eclipse-1.0.php)
+;; which can be found in the file epl-v10.html at the root of this distribution.
+;; By using this software in any fashion, you are agreeing to be bound by
+;; the terms of this license.
+;; You must not remove this notice, or any other, from this software.
+
+(ns cljs.analyzer.impl.namespaces)
+
+(defn check-and-remove-as-alias
+  "Given a libspec return a map of :as-alias alias, if was present. Return the
+   libspec with :as-alias elided. If the libspec was *only* :as-alias do not
+   return it."
+  [libspec]
+  ;; ignore simple requires (symbols) and
+  ;; REPL stuff (keywords, i.e. :reload)
+  (if (or (symbol? libspec)
+          (keyword? libspec))
+    {:libspec libspec}
+    (let [[lib & spec :as libspec] libspec
+          [pre-spec [_ alias & post-spec :as post]] (split-with (complement #{:as-alias}) spec)]
+      (if (seq post)
+        (let [libspec' (into [lib] (concat pre-spec post-spec))]
+          (assert (symbol? alias)
+            (str ":as-alias must be followed by a symbol, got: " alias))
+          (cond-> {:as-alias {alias lib}}
+            (> (count libspec') 1) (assoc :libspec libspec')))
+        {:libspec libspec}))))
+
+(defn check-as-alias-duplicates
+  [as-aliases new-as-aliases]
+  (doseq [[alias _] new-as-aliases]
+    (assert (not (contains? as-aliases alias))
+      (str "Duplicate :as-alias " alias ", already in use for lib "
+        (get as-aliases alias)))))
+
+(defn elide-aliases-from-libspecs
+  "Given libspecs, elide all :as-alias. Return a map of :libspecs (filtered)
+   and :as-aliases."
+  ([libspecs]
+   (elide-aliases-from-libspecs libspecs {}))
+  ([libspecs as-aliases]
+   (let [ret {:as-aliases as-aliases
+              :libspecs   []}]
+     (reduce
+       (fn [ret libspec]
+         (let [{:keys [as-alias libspec]} (check-and-remove-as-alias libspec)]
+           (check-as-alias-duplicates (:as-aliases ret) as-alias)
+           (cond-> ret
+             libspec  (update :libspecs conj libspec)
+             as-alias (update :as-aliases merge as-alias))))
+       ret libspecs))))
+
+(defn elide-aliases-from-ns-specs [ns-specs]
+  "Given ns specs, elide all :as-alias. Return a map of :libspecs (filtered)
+   and :as-aliases."
+  (let [ret {:as-aliases {}
+             :libspecs   []}]
+    (reduce
+      (fn [{:keys [as-aliases] :as ret} [spec-key & libspecs]]
+        (if-not (= :refer-clojure spec-key)
+          (let [{:keys [as-aliases libspecs]} (elide-aliases-from-libspecs libspecs as-aliases)]
+            (cond-> ret
+              (not (empty? as-aliases)) (update :as-aliases merge as-aliases)
+              (not (empty? libspecs))   (update :libspecs conj (list* spec-key libspecs))))
+          (update ret :libspecs conj (list* spec-key libspecs))))
+      ret ns-specs)))

src/main/clojure/cljs/repl.cljc

@@ -1146,7 +1146,7 @@
                                        reader/*data-readers* tags/*cljs-data-readers*
                                        reader/*alias-map*
                                        (apply merge
-                                         ((juxt :requires :require-macros)
+                                         ((juxt :requires :require-macros :as-aliases)
                                            (ana/get-namespace ana/*cljs-ns*)))]
                                (try
                                  (read request-prompt request-exit)

src/test/cljs_build/cljs_3346_as_alias/core.cljs

@@ -0,0 +1,5 @@
+(ns cljs-3346-as-alias.core
+  (:require [clojure.set :as-alias set]
+            [made.up.lib :as-alias lib]))
+
+(println ::set/foo ::lib/bar)

src/test/clojure/cljs/analyzer/as_alias_test.clj

@@ -0,0 +1,90 @@
+;; Copyright (c) Rich Hickey. All rights reserved.
+;; The use and distribution terms for this software are covered by the
+;; Eclipse Public License 1.0 (http://opensource.org/licenses/eclipse-1.0.php)
+;; which can be found in the file epl-v10.html at the root of this distribution.
+;; By using this software in any fashion, you are agreeing to be bound by
+;; the terms of this license.
+;; You must not remove this notice, or any other, from this software.
+
+(ns cljs.analyzer.as-alias-test
+  (:require [cljs.analyzer.impl.namespaces :as ana-nses]
+            [cljs.env :as env]
+            [clojure.test :as test :refer [deftest testing is]]))
+
+;; =============================================================================
+
+(deftest test-check-and-remove-as-alias
+  (let [cenv (env/default-compiler-env)]
+    (env/with-compiler-env cenv
+      (testing "check-and-remove-as-alias basic tests"
+        (is (= '{:as-alias {bar bar.core}}
+               (ana-nses/check-and-remove-as-alias '[bar.core :as-alias bar])))
+        (is (= '{:as-alias {bar bar.core}
+                 :libspec  [bar.core :as boo]}
+               (ana-nses/check-and-remove-as-alias '[bar.core :as-alias bar :as boo])))
+        (is (thrown? Throwable
+              (ana-nses/check-and-remove-as-alias '[bar.core :as-alias :bar]))))
+      (testing "check-and-remove-as-alias should not elide simple specs"
+        (is (= '{:libspec bar.core}
+               (ana-nses/check-and-remove-as-alias 'bar.core)))
+        (is (= '{:libspec [bar.core]}
+               (ana-nses/check-and-remove-as-alias '[bar.core])))))))
+
+(deftest test-elide-aliases-from-libspecs
+  (let [cenv (env/default-compiler-env)]
+    (env/with-compiler-env cenv
+      (is (= '{:as-aliases {foo foo.core
+                            bar bar.core
+                            woz woz.core}
+               :libspecs   [[woz.core :as wozc]]}
+            (ana-nses/elide-aliases-from-libspecs
+              '([foo.core :as-alias foo]
+                [bar.core :as-alias bar]
+                [woz.core :as-alias woz :as wozc]))))
+      (is (thrown? Throwable
+            (ana-nses/elide-aliases-from-libspecs
+              '([foo.core :as-alias foo]
+                [bar.core :as-alias bar]
+                [woz.core :as-alias woz :as wozc]
+                [foo.impl :as-alias foo])))))))
+
+(deftest test-elide-aliases-from-ns-specs
+  (let [cenv (env/default-compiler-env)]
+    (env/with-compiler-env cenv
+      (is (= '{:as-aliases {blah blah.core, foo foo.core, bar bar.core},
+               :libspecs [(:require-macros [[lala.core :as-lias lala :as tralala]])
+                          (:require [[woz.core :as woz]])]})
+        (ana-nses/elide-aliases-from-ns-specs
+          '((:require-macros [blah.core :as-alias blah]
+              [lala.core :as-alias lala :as tralala])
+            (:require
+              [foo.core :as-alias foo]
+              [bar.core :as-alias bar]
+              [woz.core :as woz]))))
+      (testing "Proper handling of ns-spec edgecases"
+        (is (= '{:as-aliases {} :libspecs [(:require foo.core bar.core woz.core)]}
+               (ana-nses/elide-aliases-from-ns-specs
+                 '((:require foo.core bar.core woz.core)))))
+        (is (= '{:as-aliases {} :libspecs [(:require [foo.core] [bar.core] [woz.core])]}
+               (ana-nses/elide-aliases-from-ns-specs
+                 '((:require [foo.core] [bar.core] [woz.core]))))))
+      (testing ":refer-clojure is ignored"
+        (is (= '{:as-aliases {}
+                 :libspecs [(:refer-clojure :exclude [first])
+                            (:require foo.core bar.core woz.core)]}
+               (ana-nses/elide-aliases-from-ns-specs
+                 '((:refer-clojure :exclude [first])
+                   (:require foo.core bar.core woz.core))))))
+      (testing ":reload/:reload-all is ignored"
+        (is (= '{:as-aliases {},
+                 :libspecs [(:refer-clojure :exclude [first])
+                            (:require foo.core bar.core woz.core :reload-all)]}
+               (ana-nses/elide-aliases-from-ns-specs
+                 '((:refer-clojure :exclude [first])
+                   (:require foo.core bar.core woz.core :reload-all)))))))))
+
+(comment
+
+  (test/run-tests)
+
+  )

src/test/clojure/cljs/build_api_tests.clj

@@ -817,3 +817,27 @@
       (.delete (io/file "package.json"))
       (test/delete-node-modules)
       (test/delete-out-files out))))
+
+(deftest test-cljs-3346-as-alias
+  (testing "Test that using :as-alias does not load the namespace, and that
+            a namespace that does not exist on file can be used."
+    (let [out (.getPath (io/file #_(test/tmp-dir) "cljs-3346-as-alias-out"))]
+      (test/delete-out-files out)
+      (test/delete-node-modules)
+      (spit (io/file "package.json") "{}")
+      (let [{:keys [inputs opts]} {:inputs (str (io/file "src" "test" "cljs_build"))
+                                   :opts {:main 'cljs-3346-as-alias.core
+                                          :output-dir out
+                                          :optimizations :none
+                                          :closure-warnings {:check-types :off}}}
+            cenv (env/default-compiler-env)]
+        (build/build (build/inputs (io/file inputs "cljs_3346_as_alias/core.cljs")) opts cenv))
+      (let [source (slurp (io/file out "cljs_3346_as_alias/core.js"))]
+        (is (true? (boolean (re-find #"goog.require\('cljs.core'\)" source))))
+        (is (false? (boolean (re-find #"goog.require\('clojure.set'\)" source))))
+        (is (false? (boolean (re-find #"goog.require\('made.up.lib'\)" source))))
+        (is (true? (boolean (re-find #"clojure\.set\/foo" source))))
+        (is (true? (boolean (re-find #"made\.up\.lib\/bar" source)))))
+      (.delete (io/file "package.json"))
+      (test/delete-node-modules)
+      (test/delete-out-files out))))

src/test/clojure/cljs/test_runner.clj

@@ -1,5 +1,6 @@
 (ns cljs.test-runner
   (:require [cljs.analyzer-api-tests]
+            [cljs.analyzer.as-alias-test]
             [cljs.analyzer-pass-tests]
             [cljs.analyzer-tests]
             [cljs.build-api-tests]
@@ -22,6 +23,7 @@
   (let [{:keys [fail error]}
         (run-tests
           'cljs.analyzer-api-tests
+          'cljs.analyzer.as-alias-test
           'cljs.analyzer-pass-tests
           'cljs.analyzer-tests
           'cljs.build-api-tests