CLJS-3294: data_readers.cljc doesn't provide a way to have target-specific behaviour (#120)

- The function that reads the data_readers.cljc files from the classpath has been moved to the analyzer ns, so that custom literals are available to the ana/forms-seq fns also.

- in cljs.reader/add-data-readers macro, the set of custom data-readers returned is the fully qualified var names of those readers - as those will be interpreted as cljs functions.

Co-authored-by: Henry Widd <henryw374@gmail.com>

Author: swannodette

src/main/cljs/cljs/reader.clj

@@ -13,6 +13,6 @@
   (let [data-readers
         (->> (get @env/*compiler* :cljs.analyzer/data-readers)
           (map (fn [[k v]]
-                 `['~k (fn [x#] (~(vary-meta v assoc :cljs.analyzer/no-resolve true) x#))]))
+                 `['~k (fn [x#] (~(vary-meta (-> v meta :sym) assoc :cljs.analyzer/no-resolve true) x#))]))
           (into {}))]
     `(do (merge ~default-readers ~data-readers))))

src/main/clojure/cljs/analyzer.cljc

@@ -618,6 +618,65 @@
 #?(:clj
    (def load-mutex (Object.)))
 
+#?(:clj
+   (defn- load-data-reader-file [mappings ^java.net.URL url]
+     (with-open [rdr (readers/input-stream-push-back-reader (.openStream url))]
+       (binding [*file* (.getFile url)]
+         (let [new-mappings (reader/read {:eof nil :read-cond :allow :features #{:cljs}} rdr)]
+           (when (not (map? new-mappings))
+             (throw (ex-info (str "Not a valid data-reader map")
+                      {:url                 url
+                       :clojure.error/phase :compilation})))
+           (reduce
+             (fn [m [k v]]
+               (when (not (symbol? k))
+                 (throw (ex-info (str "Invalid form in data-reader file")
+                          {:url                 url
+                           :form                k
+                           :clojure.error/phase :compilation})))
+               (when (and (contains? mappings k)
+                       (not= (mappings k) v))
+                 (throw (ex-info "Conflicting data-reader mapping"
+                          {:url                 url
+                           :conflict            k
+                           :mappings            m
+                           :clojure.error/phase :compilation})))
+               (assoc m k v))
+             mappings
+             new-mappings))))))
+
+#?(:clj
+   (defn get-data-readers*
+     "returns a merged map containing all data readers defined by libraries
+      on the classpath."
+     ([]
+      (get-data-readers* (. (Thread/currentThread) (getContextClassLoader))))
+     ([^ClassLoader classloader]
+      (let [data-reader-urls (enumeration-seq (. classloader (getResources "data_readers.cljc")))]
+        (reduce load-data-reader-file {} data-reader-urls)))))
+
+#?(:clj
+   (def get-data-readers (memoize get-data-readers*)))
+
+#?(:clj
+   (defn load-data-readers* []
+     (let [data-readers (get-data-readers)
+           nses (map (comp symbol namespace) (vals data-readers))]
+       (doseq [ns nses]
+         (try
+           (locking load-mutex
+             (require ns))
+           (catch Throwable _)))
+       (->> data-readers
+            (map (fn [[tag reader-fn]]
+                   [tag
+                    (-> reader-fn find-var var-get
+                        (with-meta {:sym reader-fn}))]))
+            (into {})))))
+
+#?(:clj 
+   (def load-data-readers (memoize load-data-readers*)))
+
 #?(:clj
    (defn load-core []
      (when (not @-cljs-macros-loaded)
@@ -4310,6 +4369,7 @@
              (resolve-var (assoc @env/*compiler* :ns (get-namespace *cljs-ns*))
                sym)))))
 
+
 #?(:clj
    (defn forms-seq*
      "Seq of Clojure/ClojureScript forms from rdr, a java.io.Reader. Optionally
@@ -4324,7 +4384,8 @@
                      {:read-cond :allow :features #{:cljs}}))
             pbr (readers/indexing-push-back-reader
                   (PushbackReader. rdr) 1 filename)
-            data-readers tags/*cljs-data-readers*
+            data-readers (merge tags/*cljs-data-readers*
+                           (load-data-readers))
             forms-seq_
             (fn forms-seq_ []
               (lazy-seq
@@ -4352,7 +4413,8 @@
       (let [rdr (io/reader f)
             pbr (readers/indexing-push-back-reader
                   (PushbackReader. rdr) 1 filename)
-            data-readers tags/*cljs-data-readers*
+            data-readers (merge tags/*cljs-data-readers*
+                           (load-data-readers))
             forms-seq*
             (fn forms-seq* []
               (lazy-seq

src/main/clojure/cljs/closure.clj

@@ -2976,52 +2976,9 @@
             opts js-modules)))
       opts)))
 
-(defn- load-data-reader-file [mappings ^java.net.URL url]
-  (with-open [rdr (readers/input-stream-push-back-reader (.openStream url))]
-    (binding [*file* (.getFile url)]
-      (let [new-mappings (reader/read {:eof nil :read-cond :allow} rdr)]
-        (when (not (map? new-mappings))
-          (throw (ex-info (str "Not a valid data-reader map")
-                   {:url url
-                    :clojure.error/phase :compilation})))
-        (reduce
-          (fn [m [k v]]
-            (when (not (symbol? k))
-              (throw (ex-info (str "Invalid form in data-reader file")
-                       {:url url
-                        :form k
-                        :clojure.error/phase :compilation})))
-            (when (and (contains? mappings k)
-                    (not= (mappings k) v))
-              (throw (ex-info "Conflicting data-reader mapping"
-                       {:url url
-                        :conflict k
-                        :mappings m
-                        :clojure.error/phase :compilation})))
-            (assoc m k v))
-          mappings
-          new-mappings)))))
-
-(defn get-data-readers*
-  "returns a merged map containing all data readers defined by libraries
-   on the classpath."
-  ([]
-   (get-data-readers* (. (Thread/currentThread) (getContextClassLoader))))
-  ([classloader]
-   (let [data-reader-urls (enumeration-seq (. classloader (getResources "data_readers.cljc")))]
-     (reduce load-data-reader-file {} data-reader-urls))))
-
-(def get-data-readers (memoize get-data-readers*))
-
 (defn load-data-readers! [compiler]
-  (let [data-readers (get-data-readers)
-        nses (map (comp symbol namespace) (vals data-readers))]
-    (swap! compiler update-in [:cljs.analyzer/data-readers] merge (get-data-readers))
-    (doseq [ns nses]
-      (try
-        (locking ana/load-mutex
-          (require ns))
-        (catch Throwable _)))))
+  (swap! compiler update-in [:cljs.analyzer/data-readers] merge
+    (ana/load-data-readers)))
 
 (defn add-externs-sources [opts]
   (cond-> opts

src/main/clojure/cljs/core/server.clj

@@ -91,7 +91,8 @@
                       (when (try
                               (let [[form s] (binding [*ns* (create-ns ana/*cljs-ns*)
                                                        reader/resolve-symbol ana/resolve-symbol
-                                                       reader/*data-readers* tags/*cljs-data-readers*
+                                                       reader/*data-readers* (merge tags/*cljs-data-readers*
+                                                                               (ana/load-data-readers))
                                                        reader/*alias-map*
                                                        (apply merge
                                                          ((juxt :requires :require-macros)

src/main/clojure/cljs/repl.cljc

@@ -1143,7 +1143,8 @@
                (fn []
                  (let [input (binding [*ns* (create-ns ana/*cljs-ns*)
                                        reader/resolve-symbol ana/resolve-symbol
-                                       reader/*data-readers* tags/*cljs-data-readers*
+                                       reader/*data-readers* (merge tags/*cljs-data-readers*
+                                                               (ana/load-data-readers))
                                        reader/*alias-map*
                                        (apply merge
                                          ((juxt :requires :require-macros :as-aliases)
@@ -1510,7 +1511,8 @@ itself (not its value) is returned. The reader macro #'x expands to (var x)."}})
             (let [rdr (readers/source-logging-push-back-reader pbr)]
               (dotimes [_ (dec (:line v))] (readers/read-line rdr))
               (binding [reader/*alias-map*    identity
-                        reader/*data-readers* tags/*cljs-data-readers*]
+                        reader/*data-readers* (merge tags/*cljs-data-readers*
+                                                (ana/load-data-readers))]
                 (-> (reader/read {:read-cond :allow :features #{:cljs}} rdr)
                   meta :source)))))))))
 

src/test/cljs/data_readers.cljc

@@ -9,4 +9,5 @@
 {cljs/tag clojure.core/identity
  cljs/inc clojure.core/inc
  cljs/union clojure.set/union
- test/custom-identity data-readers-test.core/custom-identity}
+ test/custom-identity data-readers-test.core/custom-identity
+ test/custom-form #?(:cljs data-readers-test.core/custom-form-cljs :clj clojure.core/identity)}

src/test/cljs/data_readers_test/core.cljc

@@ -11,3 +11,15 @@
 (def custom-identity identity)
 
 (assert (= 1 #test/custom-identity 1))
+
+(defn custom-form-cljs 
+  "a clojure and clojurescript function - in both cases targeting only cljs. 
+  
+  returns a clojurescript form (from :clj branch, when compiling) 
+  and executes js from :cljs branch when using cljs.reader/read"
+  [x]
+  #?(:clj `(js/Array.of ~x)
+     :cljs (js/Array.of x)))
+
+#?(:cljs
+   (def result #test/custom-form"foo"))

src/test/clojure/cljs/build_api_tests.clj

@@ -456,7 +456,11 @@
         cenv (env/default-compiler-env)]
     (test/delete-out-files out)
     (build/build (build/inputs (io/file inputs "data_readers_test")) opts cenv)
-    (is (contains? (-> @cenv ::ana/data-readers) 'test/custom-identity))))
+    (is (contains? (-> @cenv ::ana/data-readers) 'test/custom-identity))
+    (is (true? (boolean (re-find #"Array\.of\(\"foo\"\)"
+                          (slurp (io/file 
+                                   out ;"data-readers-test-out"
+                                   "data_readers_test" "core.js"))))))))
 
 (deftest test-data-readers-records
   (let [out (.getPath (io/file (test/tmp-dir) "data-readers-test-records-out"))