CLJS-2650: Fix JAR compilation of cljs.loader

r0man · swannodette · commit 427aaba6f557 · 2018-03-18T19:54:47.000Z
The cljs.loader file needs to be compiled after all other files to
populate the `module-infos` and `module-uris` vars. The
`requires-compilation?` function returned false if the file to compile
was cljs.loader and didn't contain a :cache-key. This prevented
`compile-from-jar` from moving the cljs.loader from the JAR file to
the disk and caused a java.io.FileNotFoundException later on.

Since cljs.loader always get compiled in a later pass, we decided to
remove this special logic.

Since this behaviour only happens when compiling from a JAR, I added a
test that uses the cljs.jar to compile the example from the Code
Splitting guide.
diff --git a/src/main/clojure/cljs/compiler.cljc b/src/main/clojure/cljs/compiler.cljc
@@ -1093,7 +1093,7 @@
 
        (or fn? js? goog?)
        (emits f "(" (comma-sep args)  ")")
-       
+
        :else
        (if (and ana/*cljs-static-fns* (= (:op f) :var))
          ;; higher order case, static information missing
@@ -1477,24 +1477,22 @@
           (:options @env/*compiler*))))
      ([^File src ^File dest opts]
       (let [{:keys [ns requires]} (ana/parse-ns src)]
-        (if (and (= 'cljs.loader ns) (not (contains? opts :cache-key)))
-          false
-          (ensure
-           (or (not (.exists dest))
-               (util/changed? src dest)
-               (let [version' (util/compiled-by-version dest)
-                     version (util/clojurescript-version)]
-                 (and version (not= version version')))
-               (and opts
-                    (not (and (io/resource "cljs/core.aot.js") (= 'cljs.core ns)))
-                    (not= (ana/build-affecting-options opts)
-                          (ana/build-affecting-options (util/build-options dest))))
-               (and opts (:source-map opts)
-                 (if (= (:optimizations opts) :none)
-                   (not (.exists (io/file (str (.getPath dest) ".map"))))
-                   (not (get-in @env/*compiler* [::compiled-cljs (.getAbsolutePath dest)]))))
-               (when-let [recompiled' (and *recompiled* @*recompiled*)]
-                 (some requires recompiled')))))))))
+        (ensure
+         (or (not (.exists dest))
+             (util/changed? src dest)
+             (let [version' (util/compiled-by-version dest)
+                   version (util/clojurescript-version)]
+               (and version (not= version version')))
+             (and opts
+                  (not (and (io/resource "cljs/core.aot.js") (= 'cljs.core ns)))
+                  (not= (ana/build-affecting-options opts)
+                        (ana/build-affecting-options (util/build-options dest))))
+             (and opts (:source-map opts)
+                  (if (= (:optimizations opts) :none)
+                    (not (.exists (io/file (str (.getPath dest) ".map"))))
+                    (not (get-in @env/*compiler* [::compiled-cljs (.getAbsolutePath dest)]))))
+             (when-let [recompiled' (and *recompiled* @*recompiled*)]
+               (some requires recompiled'))))))))
 
 #?(:clj
    (defn compile-file
diff --git a/src/test/cljs_build/hello-modules/index.html b/src/test/cljs_build/hello-modules/index.html
@@ -0,0 +1,7 @@
+<html>
+  <body>
+    <button id="button">Load Bar!</button>
+    <script src="out/cljs_base.js" type="text/javascript"></script>
+    <script src="out/foo.js" type="text/javascript"></script>
+  </body>
+</html>
diff --git a/src/test/cljs_build/hello-modules/release.clj b/src/test/cljs_build/hello-modules/release.clj
@@ -0,0 +1,13 @@
+(require '[cljs.build.api :as b])
+
+(b/build "src"
+  {:output-dir "out"
+   :asset-path "/out"
+   :optimizations :advanced
+   :verbose true
+   :modules {:foo {:entries '#{foo.core}
+                   :output-to "out/foo.js"}
+             :bar {:entries '#{bar.core}
+                   :output-to "out/bar.js"}}})
+
+(System/exit 0)
diff --git a/src/test/cljs_build/hello-modules/repl.clj b/src/test/cljs_build/hello-modules/repl.clj
@@ -0,0 +1,18 @@
+(require '[cljs.repl :as r])
+(require '[cljs.build.api :as b])
+(require '[cljs.repl.browser :as rb])
+
+(def opts
+  {:watch "src"
+   :output-dir "out"
+   :asset-path "/out"
+   :optimizations :none
+   :modules {:foo {:entries '#{foo.core}
+                   :output-to "out/foo.js"}
+             :bar {:entries '#{bar.core}
+                   :output-to "out/bar.js"}}
+   :browser-repl true
+   :verbose true})
+
+(b/build "src" opts)
+(r/repl* (rb/repl-env) opts)
diff --git a/src/test/cljs_build/hello-modules/src/bar/core.cljs b/src/test/cljs_build/hello-modules/src/bar/core.cljs
@@ -0,0 +1,11 @@
+(ns bar.core
+  (:require [cljs.loader :as loader]))
+
+(enable-console-print!)
+
+(println "I'm bar!")
+
+(defn woz []
+  (println "WOZ!"))
+
+(loader/set-loaded! :bar)
diff --git a/src/test/cljs_build/hello-modules/src/foo/core.cljs b/src/test/cljs_build/hello-modules/src/foo/core.cljs
@@ -0,0 +1,17 @@
+(ns foo.core
+  (:require [goog.dom :as gdom]
+            [goog.events :as events]
+            [cljs.loader :as loader])
+  (:import [goog.events EventType]))
+
+(enable-console-print!)
+
+(println "I'm foo!")
+
+(events/listen (gdom/getElement "button") EventType.CLICK
+  (fn [e]
+    (loader/load :bar
+      (fn []
+        ((resolve 'bar.core/woz))))))
+
+(loader/set-loaded! :foo)
diff --git a/src/test/cljs_cli/cljs_cli/test.clj b/src/test/cljs_cli/cljs_cli/test.clj
@@ -1,8 +1,9 @@
 (ns cljs-cli.test
   (:require
-   [clojure.test :refer [deftest]]
+   [clojure.test :refer [deftest is]]
    [clojure.java.io :as io]
    [clojure.java.shell :as shell :refer [with-sh-dir]]
+   [clojure.string :as str]
    [cljs-cli.util :refer [cljs-main output-is with-sources with-post-condition with-repl-env-filter]]))
 
 (deftest eval-test
@@ -68,3 +69,21 @@
       (output-is "default-value"))
     (-> (cljs-main "-co" "{:closure-defines {foo.core/configurable \"configured-value\"}}" "-m" "foo.core")
       (output-is "configured-value"))))
+
+(deftest test-cljs-2650-loader-does-not-exists
+  (doseq [optimizations [:none :advanced]]
+    (let [src (io/file "src" "test" "cljs_build" "hello-modules" "src")
+          opts {:output-dir "out"
+                :asset-path "/out"
+                :optimizations optimizations
+                :modules {:foo {:entries '#{foo.core}
+                                :output-to "out/foo.js"}
+                          :bar {:entries '#{bar.core}
+                                :output-to "out/bar.js"}}}]
+      (with-sources
+        {"src/foo/core.cljs" (slurp (io/file src "foo" "core.cljs"))
+         "src/bar/core.cljs" (slurp (io/file src "bar" "core.cljs"))}
+        (let [result (cljs-main "--compile-opts" (pr-str opts)
+                                "--compile" "foo.core")]
+          (is (zero? (:exit result)))
+          (is (str/blank? (:err result))))))))
