CLJS-2078: add resolve macro

add resolve macro. Make var-ast public and add a var-meta helper we
can use to get the var meta from the resolve macro.

Author: swannodette

src/main/clojure/cljs/analyzer.cljc

@@ -1134,7 +1134,32 @@
 
 (defmulti parse (fn [op & rest] op))
 
-(defn- var-ast
+(defn var-meta
+  ([var]
+    (var-meta var nil))
+  ([var expr-env]
+   (let [sym (:name var)
+         ks [:ns :doc :file :line :column]
+         m (merge
+             (let [user-meta (:meta var)
+                   uks (keys user-meta)]
+               (zipmap uks
+                 (map #(list 'quote (get user-meta %)) uks)))
+             (assoc (zipmap ks (map #(list 'quote (get var %)) ks))
+               :name `(quote ~(symbol (name (:name var))))
+               :test `(when ~sym (.-cljs$lang$test ~sym))
+               :arglists (let [arglists (:arglists var)
+                               arglists' (if (= 'quote (first arglists))
+                                           (second arglists)
+                                           arglists)]
+                           (list 'quote
+                             (doall (map with-meta arglists'
+                                      (:arglists-meta var)))))))]
+     (if expr-env
+       (analyze expr-env m)
+       m))))
+
+(defn var-ast
   [env sym]
   ;; we need to dissoc locals for the `(let [x 1] (def x x))` case, because we
   ;; want the var's AST and `resolve-var` will check locals first. - António Monteiro
@@ -1144,23 +1169,7 @@
     (when-some [var-ns (:ns var)]
       {:var (analyze expr-env sym)
        :sym (analyze expr-env `(quote ~(symbol (name var-ns) (name (:name var)))))
-       :meta (let [ks [:ns :doc :file :line :column]
-                   m (merge
-                       (let [user-meta (:meta var)
-                             uks (keys user-meta)]
-                         (zipmap uks
-                           (map #(list 'quote (get user-meta %)) uks)))
-                       (assoc (zipmap ks (map #(list 'quote (get var %)) ks))
-                         :name `(quote ~(symbol (name (:name var))))
-                         :test `(when ~sym (.-cljs$lang$test ~sym))
-                         :arglists (let [arglists (:arglists var)
-                                         arglists' (if (= 'quote (first arglists))
-                                                     (second arglists)
-                                                     arglists)]
-                                    (list 'quote
-                                      (doall (map with-meta arglists'
-                                               (:arglists-meta var)))))))]
-              (analyze expr-env m))})))
+       :meta (var-meta var expr-env)})))
 
 (defmethod parse 'var
   [op env [_ sym :as form] _ _]

src/main/clojure/cljs/core.cljc

@@ -37,7 +37,7 @@
                             require use refer-clojure
 
                             if-some when-some test ns-interns ns-unmap var vswap! macroexpand-1 macroexpand
-                            some?
+                            some? resolve
                             #?@(:cljs [alias coercive-not coercive-not= coercive-= coercive-boolean
                                        truth_ js-arguments js-delete js-in js-debugger exists? divide js-mod
                                        unsafe-bit-and bit-shift-right-zero-fill mask bitpos caching-hash
@@ -3144,3 +3144,16 @@
 
 #?(:clj  (. (var defmacro) (setMacro))
    :cljs (set! (. defmacro -cljs$lang$macro) true))
+
+(core/defmacro resolve
+  "Returns the var to which a symbol will be resolved in the namespace else nil."
+  [[_ sym]]
+  (core/let [env &env
+             [var meta] (try
+                          (core/let [var (ana/resolve-var env sym (ana/confirm-var-exists-throw)) ]
+                            [var (ana/var-meta var)])
+                          (catch #?@(:clj [Throwable t] :cljs [:default e])
+                            [(ana/resolve-var env sym) nil]))
+             resolved (vary-meta (:name var) assoc ::ana/no-resolve true)]
+    `(when (exists? ~resolved)
+       (cljs.core/Var. ~resolved '~resolved ~meta))))