CLJS-2592: :npm-deps using ES6 modules with .mjs extensions are not detected correctly

This adds a new :package-json-resolution option that can be used to
control which package.json entry fields are considered during JS module
resolution. As of this commit, the option accepts three values:

    :webpack (for ["browser" "module" "main"])
    :nodejs (for ["main"])
    a custom vector of entries (e.g. ["main" "module"])

If the :package-json-resolution option is not set, we fall back to the
two default modes based on the build target:

  No target => :webpack
  Target :nodejs => :nodejs

The resulting behavior:

    {:target :nodejs}  => ["main"]
    {} => ["browser", "module", "main"]

    {:target <any>
     :package-json-resolution :webpack} => ["browser", "module", "main"]

    {:target <any>
     :package-json-resolution :nodejs} => ["main"]

    {:target <any>
     :package-json-resolution ["foo", "bar"]} => ["foo", "bar"]

Using the new :nodejs mode, this allows to import packages like graphql
and iterall via :npm-deps, which currently point their "module" entries
to unsupported .mjs files.

Author: Jannis Pohlmann

src/main/cljs/cljs/module_deps.js

@@ -8,9 +8,7 @@ let enhancedResolve = require('enhanced-resolve');
 
 let target = 'CLJS_TARGET';
 let filename = fs.realpathSync(path.resolve(__dirname, 'JS_FILE'));
-let mainFields = target === 'nodejs'
-      ? ['module', 'main']
-      : ['browser', 'module', 'main'];
+let mainFields = MAIN_ENTRIES;
 let aliasFields = target === 'nodejs' ? [] : ['browser'];
 
 // https://github.com/egoist/konan

src/main/clojure/cljs/closure.clj

@@ -1769,6 +1769,35 @@
                         (.getRequires input)))
         (.toSource closure-compiler ast-root)))))
 
+(defn- package-json-entries
+  "Takes options and returns a sequence with the desired order of package.json
+   entries for the given :package-json-resolution mode. If no mode is provided,
+   defaults to :webpack (if no target is set) and :nodejs (if the target is
+   :nodejs)."
+  [opts]
+  {:pre [(or (= (:package-json-resolution opts) :webpack)
+             (= (:package-json-resolution opts) :nodejs)
+             (and (sequential? (:package-json-resolution opts))
+                  (every? string? (:package-json-resolution opts)))
+             (not (contains? opts :package-json-resolution)))]}
+  (let [modes {:nodejs ["main"]
+               :webpack ["browser" "module" "main"]}]
+    (if-let [mode (:package-json-resolution opts)]
+      (if (sequential? mode) mode (get modes mode))
+      (case (:target opts)
+        :nodejs (:nodejs modes)
+        (:webpack modes)))))
+
+(comment
+  (= (package-json-entries {}) ["browser" "module" "main"])
+  (= (package-json-entries {:package-json-resolution :nodejs}) ["main"])
+  (= (package-json-entries {:package-json-resolution :webpack}) ["browser" "module" "main"])
+  (= (package-json-entries {:package-json-resolution ["foo" "bar" "baz"]}) ["foo" "bar" "baz"])
+  (= (package-json-entries {:target :nodejs}) ["main"])
+  (= (package-json-entries {:target :nodejs :package-json-resolution :nodejs}) ["main"])
+  (= (package-json-entries {:target :nodejs :package-json-resolution :webpack}) ["browser" "module" "main"])
+  (= (package-json-entries {:target :nodejs :package-json-resolution ["foo" "bar"]}) ["foo" "bar"]))
+
 (defn convert-js-modules
   "Takes a list JavaScript modules as an IJavaScript and rewrites them into a Google
   Closure-compatible form. Returns list IJavaScript with the converted module
@@ -1781,9 +1810,8 @@
                                    (.setLanguageIn (lang-key->lang-mode :ecmascript6))
                                    (.setLanguageOut (lang-key->lang-mode (:language-out opts :ecmascript3)))
                                    (.setDependencyOptions (doto (DependencyOptions.)
-                                                            (.setDependencySorting true))))
-        _ (when (= (:target opts) :nodejs)
-            (.setPackageJsonEntryNames options ^List '("module", "main")))
+                                                            (.setDependencySorting true)))
+                                   (.setPackageJsonEntryNames ^List (package-json-entries opts)))
         closure-compiler (doto (make-closure-compiler)
                            (.init externs source-files options))
         _ (.parse closure-compiler)
@@ -2322,9 +2350,13 @@
      (when env/*compiler*
        (:options @env/*compiler*))))
   ([{:keys [file]} {:keys [target] :as opts}]
-   (let [code (-> (slurp (io/resource "cljs/module_deps.js"))
+   (let [main-entries (str "[" (->> (package-json-entries opts)
+                                    (map #(str "\"" % "\""))
+                                    (string/join ",")) "]")
+         code (-> (slurp (io/resource "cljs/module_deps.js"))
                 (string/replace "JS_FILE" (string/replace file "\\" "\\\\"))
-                (string/replace "CLJS_TARGET" (str "" (when target (name target)))))
+                (string/replace "CLJS_TARGET" (str "" (when target (name target))))
+                (string/replace "MAIN_ENTRIES" main-entries))
          proc (-> (ProcessBuilder. ["node" "--eval" code])
                 .start)
          is   (.getInputStream proc)

src/test/cljs_build/package_json_resolution_test/core.cljs

@@ -0,0 +1,8 @@
+(ns package-json-resolution-test.core
+  (:require [iterall]
+            [graphql]))
+
+(enable-console-print!)
+
+(println "Is collection:" (iterall/isCollection #js [1 2]))
+(println "GraphQL:" graphql)

src/test/clojure/cljs/build_api_tests.clj

@@ -573,3 +573,56 @@
       (let [content (slurp (-> opts :modules :c :output-to))]
         (testing "requires code.split.c"
           (is (test/document-write? content 'code.split.c)))))))
+
+(deftest test-cljs-2592
+  (test/delete-node-modules)
+  (spit (io/file "package.json") "{}")
+  (let [cenv (env/default-compiler-env)
+        dir (io/file "src" "test" "cljs_build" "package_json_resolution_test")
+        out (io/file (test/tmp-dir) "package_json_resolution_test")
+        opts {:main 'package-json-resolution-test.core
+              :output-dir (str out)
+              :output-to (str (io/file out "main.js"))
+              :optimizations :none
+              :install-deps true
+              :npm-deps {:iterall "1.2.2"
+                         :graphql "0.13.1"}
+              :package-json-resolution :nodejs
+              :closure-warnings {:check-types :off
+                                 :non-standard-jsdoc :off}}]
+    (test/delete-out-files out)
+    (build/build (build/inputs dir) opts cenv)
+    (testing "processes the iterall index.js"
+      (let [index-js (io/file out "node_modules/iterall/index.js")]
+        (is (.exists index-js))
+        (is (contains? (:js-module-index @cenv) "iterall"))
+        (is (re-find #"goog\.provide\(\"module\$.*\$node_modules\$iterall\$index\"\)" (slurp index-js)))))
+    (testing "processes the graphql index.js"
+      (let [index-js (io/file out "node_modules/graphql/index.js")
+            execution-index-js (io/file out "node_modules/graphql/execution/index.js")
+            ast-from-value-js (io/file out "node_modules/grapqhl/utilities/astFromValue.js")]
+        (is (.exists index-js))
+        (is (contains? (:js-module-index @cenv) "graphql"))
+        (is (re-find  #"goog\.provide\(\"module\$.*\$node_modules\$graphql\$index\"\)" (slurp index-js)))))
+    (testing "processes a nested index.js in graphql"
+      (let [nested-index-js (io/file out "node_modules/graphql/execution/index.js")]
+        (is (.exists nested-index-js))
+        (is (contains? (:js-module-index @cenv) "graphql/execution"))
+        (is (re-find  #"goog\.provide\(\"module\$.*\$node_modules\$graphql\$execution\$index\"\)" (slurp nested-index-js)))))
+    (testing "processes cross-package imports"
+      (let [ast-from-value-js (io/file out "node_modules/graphql/utilities/astFromValue.js")]
+        (is (.exists ast-from-value-js))
+        (is (re-find #"goog.require\(\"module\$.*\$node_modules\$iterall\$index\"\);" (slurp ast-from-value-js)))))
+    (testing "adds dependencies to cljs_deps.js"
+      (let [deps-js (io/file out "cljs_deps.js")]
+        (is (re-find #"goog\.addDependency\(\"..\/node_modules\/iterall\/index.js\"" (slurp deps-js)))
+        (is (re-find #"goog\.addDependency\(\"..\/node_modules\/graphql\/index.js\"" (slurp deps-js)))
+        (is (re-find #"goog\.addDependency\(\"..\/node_modules\/graphql\/execution/index.js\"" (slurp deps-js)))))
+    (testing "adds the right module names to the core.cljs build output"
+      (let [core-js (io/file out "package_json_resolution_test/core.js")]
+        (is (re-find #"goog\.require\('module\$.*\$node_modules\$iterall\$index'\);" (slurp core-js)))
+        (is (re-find #"module\$.+\$node_modules\$iterall\$index\[\"default\"\]\.isCollection" (slurp core-js)))
+        (is (re-find #"goog\.require\('module\$.*\$node_modules\$graphql\$index'\);" (slurp core-js)))
+        (is (re-find  #"module\$.+\$node_modules\$graphql\$index\[\"default\"\]" (slurp core-js))))))
+  (.delete (io/file "package.json"))
+  (test/delete-node-modules))

src/test/clojure/cljs/closure_tests.clj

@@ -442,3 +442,38 @@
     (.delete (io/file "package.json"))
     (test/delete-node-modules)
     (test/delete-out-files out)))
+
+(deftest test-cljs-2592
+  (spit (io/file "package.json") "{}")
+  (let [opts {:npm-deps {:iterall "1.2.2"
+                         :graphql "0.13.1"}
+              :package-json-resolution :nodejs}
+        out  (util/output-directory opts)]
+    (test/delete-node-modules)
+    (test/delete-out-files out)
+    (closure/maybe-install-node-deps! opts)
+    (let [modules (closure/index-node-modules ["iterall" "graphql"] opts)]
+      (is (true? (some (fn [module]
+                         (= module {:module-type :es6
+                                    :file (.getAbsolutePath (io/file "node_modules/iterall/index.js"))
+                                    :provides ["iterall"
+                                               "iterall/index.js"
+                                               "iterall/index"]}))
+                       modules)))
+      (is (true? (some (fn [module]
+                         (= module {:module-type :es6
+                                    :file (.getAbsolutePath (io/file "node_modules/graphql/index.js"))
+                                    :provides ["graphql"
+                                               "graphql/index.js"
+                                               "graphql/index"]}))
+                       modules)))
+      (is (true? (some (fn [module]
+                         (= module {:module-type :es6
+                                    :file (.getAbsolutePath (io/file "node_modules/graphql/execution/index.js"))
+                                    :provides ["graphql/execution/index.js"
+                                               "graphql/execution/index"
+                                               "graphql/execution"]}))
+                       modules))))
+    (.delete (io/file "package.json"))
+    (test/delete-node-modules)
+    (test/delete-out-files out)))