Add a build setting to the Apple transitions that dependencies can be used to determine if they're being built into an Apple bundle or not.

Cherry-pick: d810748

Author: allevato

apple/build_settings/build_settings.bzl

@@ -71,6 +71,17 @@ Controls the output format for dSYM debug symbols. Valid values are:
 # List of all registered build settings without command line flags at
 # `rules_apple/apple/build_settings/BUILD`.
 build_settings = {
+    "building_apple_bundle": struct(
+        doc = """
+This is set to True if the target configuration is building a bundled Apple
+binary. For example, an `ios_application`, `watchos_extension`, or
+`macos_unit_test`, but *not* a `macos_command_line_application`.
+
+This can be tested by clients to provide conditional behavior depending on
+whether or not a library is being built as a dependency of a bundled executable.
+""",
+        default = False,
+    ),
     "enable_wip_features": struct(
         doc = """
 Enables functionality that is still a work in progress, with interfaces and output that can change

apple/internal/rule_attrs.bzl

@@ -545,6 +545,13 @@ appropriate resources location within the bundle.
             doc = """
 An `apple_bundle_version` target that represents the version for this target. See
 [`apple_bundle_version`](https://github.com/bazelbuild/rules_apple/blob/main/doc/rules-general.md?cl=head#apple_bundle_version).
+""",
+        ),
+        "_building_apple_bundle": attr.bool(
+            default = True,
+            doc = """
+Internal attribute read by Apple rule transitions to set the
+`building_apple_bundle` build setting.
 """,
         ),
     }

apple/internal/transition_support.bzl

@@ -304,6 +304,7 @@ def _is_arch_supported_for_target_tuple(*, environment_arch, minimum_os_version,
 def _command_line_options(
         *,
         apple_platforms = [],
+        building_apple_bundle = False,
         environment_arch = None,
         force_bundle_outputs = False,
         minimum_os_version,
@@ -318,6 +319,8 @@ def _command_line_options(
             first element will be applied to `platforms` as that will be what is resolved by the
             underlying rule. Defaults to an empty list, which will signal to Bazel that platform
             mapping can take place as a fallback measure.
+        building_apple_bundle: Indicates if the rule is building a bundle (rather than a
+            standalone executable or library).
         environment_arch: A valid Apple environment when applicable with its architecture as a
             string (for example `sim_arm64` from `ios_sim_arm64`, or `arm64` from `ios_arm64`), or
             None to infer a value from command line options passed through settings.
@@ -343,6 +346,7 @@ def _command_line_options(
 
     default_platforms = [settings[_CPU_TO_DEFAULT_PLATFORM_FLAG[cpu]]] if _is_bazel_7 else []
     return {
+        build_settings_labels.building_apple_bundle: building_apple_bundle,
         build_settings_labels.use_tree_artifacts_outputs: force_bundle_outputs if force_bundle_outputs else settings[build_settings_labels.use_tree_artifacts_outputs],
         "//command_line_option:apple_platform_type": platform_type,
         "//command_line_option:apple_platforms": apple_platforms,
@@ -411,6 +415,7 @@ def _resolved_environment_arch_for_arch(*, arch, environment, platform_type):
 
 def _command_line_options_for_xcframework_platform(
         *,
+        building_apple_bundle,
         minimum_os_version,
         platform_attr,
         platform_type,
@@ -419,6 +424,8 @@ def _command_line_options_for_xcframework_platform(
     """Generates a dictionary of command line options keyed by 1:2+ transition for this platform.
 
     Args:
+        building_apple_bundle: Indicates if the rule is building a bundle (rather than a
+            standalone executable or library).
         minimum_os_version: A string representing the minimum OS version specified for this
             platform, represented as a dotted version number (for example, `"9.0"`).
         platform_attr: The attribute for the apple platform specifying in dictionary form which
@@ -453,6 +460,7 @@ def _command_line_options_for_xcframework_platform(
                     environment = target_environment,
                     platform_type = platform_type,
                 ): _command_line_options(
+                    building_apple_bundle = building_apple_bundle,
                     environment_arch = resolved_environment_arch,
                     minimum_os_version = minimum_os_version,
                     platform_type = platform_type,
@@ -467,7 +475,9 @@ def _apple_rule_base_transition_impl(settings, attr):
     """Rule transition for Apple rules using Bazel CPUs and a valid Apple split transition."""
     minimum_os_version = attr.minimum_os_version
     platform_type = attr.platform_type
+    building_apple_bundle = getattr(attr, "_building_apple_bundle", False)
     return _command_line_options(
+        building_apple_bundle = building_apple_bundle,
         environment_arch = _environment_archs(platform_type, minimum_os_version, settings)[0],
         minimum_os_version = minimum_os_version,
         platform_type = platform_type,
@@ -496,6 +506,7 @@ _apple_platform_transition_inputs = _apple_platforms_rule_base_transition_inputs
     "//command_line_option:platforms",
 ]
 _apple_rule_base_transition_outputs = [
+    build_settings_labels.building_apple_bundle,
     build_settings_labels.use_tree_artifacts_outputs,
     "//command_line_option:apple_platform_type",
     "//command_line_option:apple_platforms",
@@ -528,12 +539,14 @@ def _apple_platforms_rule_base_transition_impl(settings, attr):
     """Rule transition for Apple rules using Bazel platforms and the Starlark split transition."""
     minimum_os_version = attr.minimum_os_version
     platform_type = attr.platform_type
+    building_apple_bundle = getattr(attr, "_building_apple_bundle", False)
     environment_arch = None
     if not settings["//command_line_option:incompatible_enable_apple_toolchain_resolution"]:
         # Add fallback to match an anticipated split of Apple cpu-based resolution
         environment_arch = _environment_archs(platform_type, minimum_os_version, settings)[0]
     return _command_line_options(
         apple_platforms = settings["//command_line_option:apple_platforms"],
+        building_apple_bundle = building_apple_bundle,
         environment_arch = environment_arch,
         minimum_os_version = minimum_os_version,
         platform_type = platform_type,
@@ -550,6 +563,7 @@ def _apple_platforms_rule_bundle_output_base_transition_impl(settings, attr):
     """Rule transition for Apple rules using Bazel platforms which force bundle outputs."""
     minimum_os_version = attr.minimum_os_version
     platform_type = attr.platform_type
+    building_apple_bundle = getattr(attr, "_building_apple_bundle", False)
     environment_arch = None
     if not settings["//command_line_option:incompatible_enable_apple_toolchain_resolution"]:
         # Add fallback to match an anticipated split of Apple cpu-based resolution
@@ -560,6 +574,7 @@ def _apple_platforms_rule_bundle_output_base_transition_impl(settings, attr):
         )
     return _command_line_options(
         apple_platforms = settings["//command_line_option:apple_platforms"],
+        building_apple_bundle = building_apple_bundle,
         environment_arch = environment_arch[0],
         force_bundle_outputs = True,
         minimum_os_version = minimum_os_version,
@@ -656,6 +671,7 @@ def _apple_platform_split_transition_impl(settings, attr):
             if str(platform) not in output_dictionary:
                 output_dictionary[str(platform)] = _command_line_options(
                     apple_platforms = apple_platforms,
+                    building_apple_bundle = getattr(attr, "_building_apple_bundle", False),
                     minimum_os_version = attr.minimum_os_version,
                     platform_type = attr.platform_type,
                     settings = settings,
@@ -664,6 +680,7 @@ def _apple_platform_split_transition_impl(settings, attr):
     else:
         minimum_os_version = attr.minimum_os_version
         platform_type = attr.platform_type
+        building_apple_bundle = getattr(attr, "_building_apple_bundle", False)
         for environment_arch in _environment_archs(platform_type, minimum_os_version, settings):
             found_cpu = _cpu_string(
                 environment_arch = environment_arch,
@@ -704,6 +721,7 @@ def _apple_platform_split_transition_impl(settings, attr):
                 continue
 
             output_dictionary[found_cpu] = _command_line_options(
+                building_apple_bundle = building_apple_bundle,
                 environment_arch = environment_arch,
                 minimum_os_version = minimum_os_version,
                 platform_type = platform_type,
@@ -772,6 +790,7 @@ def _xcframework_split_transition_impl(settings, attr):
             target_environments.append("simulator")
 
         command_line_options = _command_line_options_for_xcframework_platform(
+            building_apple_bundle = getattr(attr, "_building_apple_bundle", False),
             minimum_os_version = attr.minimum_os_versions.get(platform_type),
             platform_attr = platform_attr,
             platform_type = platform_type,

test/starlark_tests/macos_application_tests.bzl

@@ -443,6 +443,17 @@ def macos_application_test_suite(name):
         tags = [name],
     )
 
+    archive_contents_test(
+        name = "{}_is_building_apple_bundle_test".format(name),
+        build_type = "simulator",
+        target_under_test = "//test/starlark_tests/targets_under_test/macos:bundled_app_to_test_building_apple_bundle",
+        binary_test_file = "$CONTENT_ROOT/MacOS/bundled_app_to_test_building_apple_bundle",
+        binary_test_architecture = "x86_64",
+        binary_contains_symbols = ["_IsBuildingAppleBundle"],
+        binary_not_contains_symbols = ["_IsNotBuildingAppleBundle"],
+        tags = [name],
+    )
+
     archive_contents_test(
         name = "{}_archive_contains_ccinfo_deps_dylibs_test".format(name),
         build_type = "simulator",

test/starlark_tests/macos_command_line_application_tests.bzl

@@ -294,6 +294,17 @@ def macos_command_line_application_test_suite(name):
         tags = [name],
     )
 
+    binary_contents_test(
+        name = "{}_is_building_apple_bundle_test".format(name),
+        build_type = "device",
+        target_under_test = "//test/starlark_tests/targets_under_test/macos:cmd_app_to_test_building_apple_bundle",
+        binary_test_file = "$BINARY",
+        binary_test_architecture = "x86_64",
+        binary_contains_symbols = ["_IsNotBuildingAppleBundle"],
+        binary_not_contains_symbols = ["_IsBuildingAppleBundle"],
+        tags = [name],
+    )
+
     native.test_suite(
         name = name,
         tags = [name],

test/starlark_tests/targets_under_test/macos/BUILD

@@ -3039,3 +3039,57 @@ apple_static_xcframework(
     tags = common.fixture_tags,
     deps = [":fmwk_lib"],
 )
+
+# ---------------------------------------------------------------------------------------
+# Tests for the `building_apple_bundle` build setting.
+
+config_setting(
+    name = "is_building_apple_bundle",
+    flag_values = {
+        "//apple/build_settings:building_apple_bundle": "True",
+    },
+)
+
+genrule(
+    name = "is_building_apple_bundle_src",
+    outs = ["IsBuildingAppleBundle.m"],
+    cmd = """
+cat > $@ <<'EOF'
+__attribute__((used)) void IS_BUILDING_APPLE_BUNDLE_SYMBOL() {}
+int main() { return 0; }
+EOF
+""",
+    tags = common.fixture_tags,
+)
+
+objc_library(
+    name = "is_building_apple_bundle_lib",
+    srcs = ["IsBuildingAppleBundle.m"],
+    copts = select({
+        ":is_building_apple_bundle": ["-DIS_BUILDING_APPLE_BUNDLE_SYMBOL=IsBuildingAppleBundle"],
+        "//conditions:default": ["-DIS_BUILDING_APPLE_BUNDLE_SYMBOL=IsNotBuildingAppleBundle"],
+    }),
+    tags = common.fixture_tags,
+)
+
+macos_command_line_application(
+    name = "cmd_app_to_test_building_apple_bundle",
+    minimum_os_version = common.min_os_macos.baseline,
+    tags = common.fixture_tags,
+    deps = [
+        ":is_building_apple_bundle_lib",
+    ],
+)
+
+macos_application(
+    name = "bundled_app_to_test_building_apple_bundle",
+    bundle_id = "com.google.example",
+    infoplists = [
+        "//test/starlark_tests/resources:Info.plist",
+    ],
+    minimum_os_version = common.min_os_macos.baseline,
+    tags = common.fixture_tags,
+    deps = [
+        ":is_building_apple_bundle_lib",
+    ],
+)