Sync xcframework_rules with upstream

Author: luispadron

apple/internal/swift_support.bzl

@@ -14,11 +14,80 @@
 
 """Support functions for working with Swift."""
 
+load("@build_bazel_rules_swift//swift:providers.bzl", "SwiftInfo")
 load(
     "//apple/internal/aspects:swift_usage_aspect.bzl",
     "SwiftUsageInfo",
 )
 
+visibility([
+    "//apple/...",
+    "//test/...",
+])
+
+def _has_only_one_non_system_swift_module(*, target):
+    """Indicates if the given target references any non-system Swift modules.
+
+    Args:
+        target: A Target representing a dep for a given split from `deps` on the XCFramework rule.
+
+    Returns:
+        `True` if a non-system module was found from the target's SwiftInfo provider, `False`
+        otherwise.
+    """
+    if SwiftInfo not in target:
+        return False
+
+    module_names = []
+
+    # Covers both direct and transitive modules, from how the SwiftInfo provider is constructed.
+    for module in target[SwiftInfo].transitive_modules.to_list():
+        if module.swift and not module.is_system:
+            module_names.append(module.name)
+
+    # If there is more than one non-system Swift module in the transitive modules, then there is an
+    # invalid Swift module dependency present within deps.
+    if len(module_names) > 1:
+        fail("""
+Error: Found more than one Swift module dependency in this XCFramework's deps: \
+{module_names}
+
+Check that you are only referencing ONE Swift module, such as from a a swift_library rule, and \
+that there are no additional Swift modules referenced outside of its private_deps, such as from an \
+additional swift_library dependency.
+        """.format(module_names = ", ".join(module_names)))
+
+    return bool(module_names)
+
+def _target_supporting_swift_xcframework_interfaces(targets):
+    """Returns a target with SwiftInfo capable of supporting Swift XCFramework interfaces.
+
+    If there are issues with the dependencies found, they will be raised as failures during the
+    build's analysis phase.
+
+    Args:
+        targets: A List of Targets representing `deps` for a given split on the XCFramework rule.
+
+    Returns:
+        A target referencing a `SwiftInfo` provider if a module capable of supporting Swift
+        XCFramework interfaces was found, `None` if not.
+    """
+
+    direct_swift_module = None
+
+    for target in targets:
+        if _has_only_one_non_system_swift_module(target = target):
+            # Check that there's only one direct Swift module in an XCFramework rule's deps.
+            if not direct_swift_module:
+                direct_swift_module = target
+            else:
+                fail("""
+Error: Found more than one non-system Swift module in the deps of this XCFramework rule. Check \
+that you are not directly referencing more than one swift_library rule in the deps of the rule.
+                """)
+
+    return direct_swift_module
+
 def _uses_swift(targets):
     """Returns True if any of the given targets uses Swift.
 
@@ -40,5 +109,6 @@ def _uses_swift(targets):
 
 # Define the loadable module that lists the exported symbols in this file.
 swift_support = struct(
+    target_supporting_swift_xcframework_interfaces = _target_supporting_swift_xcframework_interfaces,
     uses_swift = _uses_swift,
 )

apple/internal/transition_support.bzl

@@ -72,6 +72,12 @@ _IOS_ARCH_TO_64_BIT_WATCHOS = {
     "arm64": "arm64_32",
 }
 
+# Set the default architecture for all platforms as 64-bit Intel.
+# TODO(b/246375874): Consider changing the default when a build is invoked from an Apple Silicon
+# Mac. The --host_cpu command line option is not guaranteed to reflect the actual host device that
+# dispatched the invocation.
+_DEFAULT_ARCH = "x86_64"
+
 def _platform_specific_cpu_setting_name(platform_type):
     """Returns the name of a platform-specific CPU setting.
 
@@ -433,7 +439,8 @@ def _command_line_options_for_xcframework_platform(
     for target_environment in target_environments:
         if not platform_attr.get(target_environment):
             continue
-        for arch in platform_attr[target_environment]:
+        sorted_target_archs = sorted(platform_attr[target_environment])
+        for arch in sorted_target_archs:
             resolved_environment_arch = _resolved_environment_arch_for_arch(
                 arch = arch,
                 environment = target_environment,
@@ -727,12 +734,30 @@ _apple_platform_split_transition = transition(
     outputs = _apple_rule_base_transition_outputs,
 )
 
-def _xcframework_transition_impl(settings, attr):
+def _xcframework_base_transition_impl(settings, _):
+    """Rule transition for XCFramework rules producing SDK-adjacent artifacts."""
+
+    # For safety, lean on darwin_{default arch} with no incoming minimum_os_version to avoid
+    # incoming settings meant for other platforms overriding the settings for the xcframework rule's
+    # underlying actions, and allow for toolchain resolution in the future.
+    return _command_line_options(
+        environment_arch = _DEFAULT_ARCH,
+        minimum_os_version = None,
+        platform_type = "macos",
+        settings = settings,
+    )
+
+_xcframework_base_transition = transition(
+    implementation = _xcframework_base_transition_impl,
+    inputs = _apple_rule_common_transition_inputs,
+    outputs = _apple_rule_base_transition_outputs,
+)
+
+def _xcframework_split_transition_impl(settings, attr):
     """Starlark 1:2+ transition for generation of multiple frameworks for the current target."""
     output_dictionary = {}
 
-    # TODO(b/288582842): Update for visionOS when we're ready to support it in XCFramework rules.
-    for platform_type in ["ios", "tvos", "visionos", "watchos", "macos"]:
+    for platform_type in ["ios", "tvos", "watchos", "visionos", "macos"]:
         platform_attr = getattr(attr, platform_type, None)
         if not platform_attr:
             continue
@@ -751,7 +776,7 @@ def _xcframework_transition_impl(settings, attr):
             platform_attr = platform_attr,
             platform_type = platform_type,
             settings = settings,
-            target_environments = target_environments,
+            target_environments = sorted(target_environments),
         )
         output_dictionary = dicts.add(command_line_options, output_dictionary)
 
@@ -761,8 +786,8 @@ def _xcframework_transition_impl(settings, attr):
 
     return output_dictionary
 
-_xcframework_transition = transition(
-    implementation = _xcframework_transition_impl,
+_xcframework_split_transition = transition(
+    implementation = _xcframework_split_transition_impl,
     inputs = _apple_rule_common_transition_inputs,
     outputs = _apple_rule_base_transition_outputs,
 )
@@ -775,5 +800,6 @@ transition_support = struct(
     apple_rule_transition = _apple_rule_base_transition,
     apple_universal_binary_rule_transition = _apple_universal_binary_rule_transition,
     xcframework_split_attr_key = _xcframework_split_attr_key,
-    xcframework_transition = _xcframework_transition,
+    xcframework_base_transition = _xcframework_base_transition,
+    xcframework_split_transition = _xcframework_split_transition,
 )