Add obfuscated-hrp primary.prof as a buildable file.

PiperOrigin-RevId: 843395626
Change-Id: I07a789d8e77da500c2783eeecd27b46dbe8ddb96

Author: A Googler

providers/providers.bzl

@@ -289,6 +289,7 @@ ArtProfileInfo = provider(
         art_profile_zip = "Zip file containing the baseline profile and metadata, intended to be merged into APK.",
         baseline_profile = "Generated baseline.prof file",
         baseline_profile_metadata = "Generated baseline.profm file",
+        primary_profile = "Generated primary.prof file",
     ),
 )
 

rules/android_binary/impl.bzl

@@ -152,7 +152,7 @@ def _validate_manifest(ctx, packaged_resources_ctx, manifest_ctx, **unused_ctxs)
         ),
     )
 
-def _process_native_libs(ctx, **_unusued_ctxs):
+def _process_native_libs(ctx, **_unused_ctxs):
     providers = []
     native_libs_info = _process_native_deps(
         ctx,
@@ -710,6 +710,7 @@ def _process_baseline_profiles(ctx, validation_ctx, deploy_ctx, **_unused_ctxs):
 def _process_art_profile(ctx, validation_ctx, bp_ctx, dex_ctx, optimize_ctx, **_unused_ctxs):
     providers = []
     art_profile_info = None
+
     if ctx.attr.generate_art_profile and not validation_ctx.use_r8:
         merged_baseline_profile = bp_ctx.baseline_profile_output.baseline_profile
         merged_baseline_profile_rewritten = \
@@ -731,12 +732,23 @@ def _process_art_profile(ctx, validation_ctx, bp_ctx, dex_ctx, optimize_ctx, **_
                 ctx,
                 final_classes_dex = dex_ctx.dex_info.final_classes_dex_zip,
                 merged_profile = merged_baseline_profile,
+                output_primary_profile = ctx.outputs.primary_profile,
                 proguard_output_map = proguard_output_map,
                 profgen = get_android_toolchain(ctx).profgen.files_to_run,
                 toolchain_type = ANDROID_TOOLCHAIN_TYPE,
             )
             providers.append(art_profile_info)
 
+    if ctx.attr.generate_art_profile and not art_profile_info:
+        # There are a lot of ways baseline profiles could fail, and thus art profile generation also
+        # fails. For example, if the baseline profile is not included as a dependency, if the
+        # baseline profile is empty, or if you're attempting to use R8.
+        ctx.actions.run_shell(
+            mnemonic = "FailedGeneratingArtProfile",
+            outputs = [ctx.outputs.primary_profile],
+            command = "echo \"Unable to generate art profile, ensure baseline profiles are included as dependencies or disable generate_art_profile\"; exit 1;",
+        )
+
     return ProviderInfo(
         name = "ap_ctx",
         value = struct(

rules/android_binary/rule.bzl

@@ -31,7 +31,7 @@ _DEFAULT_ALLOWED_ATTRS = ["name", "visibility", "tags", "testonly", "transitive_
 
 _DEFAULT_PROVIDES = [ApkInfo, JavaInfo]
 
-def _outputs(name, proguard_generate_mapping, _package_name, _generate_proguard_outputs):
+def _outputs(name, proguard_generate_mapping, _package_name, _generate_proguard_outputs, generate_art_profile):
     label = "//" + _package_name + ":" + name
 
     outputs = dict(
@@ -50,6 +50,10 @@ def _outputs(name, proguard_generate_mapping, _package_name, _generate_proguard_
         outputs["proguard_config"] = "%{name}_proguard.config"
         if proguard_generate_mapping:
             outputs["proguard_map"] = "%{name}_proguard.map"
+
+    if generate_art_profile:
+        outputs["primary_profile"] = "%{name}_primary.prof"
+
     return outputs
 
 def make_rule(

rules/baseline_profiles.bzl

@@ -104,6 +104,7 @@ def _process_art_profile(
         ctx,
         final_classes_dex,
         merged_profile,
+        output_primary_profile,
         proguard_output_map = None,
         profgen = None,
         toolchain_type = None):
@@ -124,27 +125,17 @@ def _process_art_profile(
       ArtProfileInfo containing the generated profile, the metadata, and the combined zip file.
     """
 
-    # Profgen
     output_profile = _get_profile_artifact(ctx, "baseline.prof")
     output_profile_meta = _get_profile_artifact(ctx, "baseline.profm")
-    profgen_inputs = [final_classes_dex, merged_profile]
-    profgen_args = ctx.actions.args()
-    profgen_args.add("bin", merged_profile)
-    profgen_args.add("--apk", final_classes_dex)
-    profgen_args.add("--output", output_profile)
-    profgen_args.add("--output-meta", output_profile_meta)
-    if proguard_output_map:
-        profgen_args.add("--map", proguard_output_map)
-        profgen_inputs.append(proguard_output_map)
-    ctx.actions.run(
-        mnemonic = "GenerateARTProfile",
-        executable = profgen,
-        progress_message = "Generating Android P-R ART profile for %{label} APK",
-        arguments = [profgen_args],
-        inputs = profgen_inputs,
-        outputs = [output_profile, output_profile_meta],
-        use_default_shell_env = True,
-        toolchain = toolchain_type,
+    _generate_profile(
+        ctx,
+        output_profile,
+        output_profile_meta,
+        final_classes_dex,
+        merged_profile,
+        proguard_output_map,
+        profgen,
+        toolchain_type,
     )
 
     # Zip ART profiles
@@ -161,10 +152,21 @@ def _process_art_profile(
         resources = [output_profile, output_profile_meta],
         java_toolchain = _common.get_java_toolchain(ctx),
     )
+
+    _dump_profile(
+        ctx,
+        output_primary_profile,
+        output_profile,
+        final_classes_dex,
+        profgen,
+        toolchain_type,
+    )
+
     return ArtProfileInfo(
         art_profile_zip = output_profile_zip,
         baseline_profile = output_profile,
         baseline_profile_metadata = output_profile_meta,
+        primary_profile = output_primary_profile,
     )
 
 def _get_profile_dir(ctx):
@@ -216,6 +218,60 @@ def _expand_wildcards(
         toolchain = toolchain_type,
     )
 
+def _generate_profile(
+        ctx,
+        output_profile,
+        output_profile_meta,
+        final_classes_dex,
+        merged_profile,
+        proguard_output_map = None,
+        profgen = None,
+        toolchain_type = None):
+    profgen_inputs = [final_classes_dex, merged_profile]
+    args = ctx.actions.args()
+    args.add("bin", merged_profile)
+    args.add("--apk", final_classes_dex)
+    args.add("--output", output_profile)
+    args.add("--output-meta", output_profile_meta)
+    if proguard_output_map:
+        args.add("--map", proguard_output_map)
+        profgen_inputs.append(proguard_output_map)
+
+    ctx.actions.run(
+        mnemonic = "GenerateARTProfile",
+        executable = profgen,
+        progress_message = "Generating Android P-R ART profile for %{label} APK",
+        arguments = [args],
+        inputs = profgen_inputs,
+        outputs = [output_profile, output_profile_meta],
+        use_default_shell_env = True,
+        toolchain = toolchain_type,
+    )
+
+def _dump_profile(
+        ctx,
+        output,
+        binary_profile,
+        final_classes_dex,
+        profgen = None,
+        toolchain_type = None):
+    args = ctx.actions.args()
+    args.add("dumpProfile")
+    args.add("--profile", binary_profile)
+    args.add("--apk", final_classes_dex)
+    args.add("--output", output)
+
+    ctx.actions.run(
+        mnemonic = "DumpProfile",
+        executable = profgen,
+        progress_message = "Dumping Obfuscated-HRP profile for %{label} APK",
+        arguments = [args],
+        inputs = [binary_profile, final_classes_dex],
+        outputs = [output],
+        use_default_shell_env = True,
+        toolchain = toolchain_type,
+    )
+
 baseline_profiles = struct(
     expand_wildcards = _expand_wildcards,
     get_profile_artifact = _get_profile_artifact,