extractor: Setup signing for CI snapshots

Signed-off-by: Aayush Gupta <aayushgupta219@gmail.com>

Author: theimpulson

.github/workflows/snapshot.yml

@@ -0,0 +1,28 @@
+name: Publish snapshot
+
+on:
+  push:
+    branches:
+      - dev
+
+jobs:
+  build-and-deploy-docs:
+    runs-on: ubuntu-latest
+    steps:
+      - uses: actions/checkout@v6
+
+      - name: set up JDK
+        uses: actions/setup-java@v5
+        with:
+          java-version: 21
+          distribution: 'temurin'
+
+      - name: Cache Gradle dependencies
+        uses: actions/cache@v5
+        with:
+          path: ~/.gradle/caches
+          key: ${{ runner.os }}-gradle-${{ hashFiles('**/*.gradle') }}
+          restore-keys: ${{ runner.os }}-gradle
+
+      - name: Publish snapshot
+        run: ./gradlew publishSnapshotPublicationToSonatypeRepository

extractor/build.gradle.kts

@@ -6,10 +6,16 @@
 import org.gradle.api.tasks.testing.logging.TestExceptionFormat
 import org.gradle.api.tasks.testing.logging.TestLogEvent
 
+val ciSigningKey: String? = System.getenv("PGP_PRIVATE_SIGNING_KEY")
+val ciSigningPassword: String? = System.getenv("PGP_PRIVATE_SIGNING_KEY_PASSWORD")
+val shouldSignRelease: Boolean
+    get() = !ciSigningKey.isNullOrEmpty() && !ciSigningPassword.isNullOrEmpty()
+
 plugins {
     alias(libs.plugins.google.protobuf)
     checkstyle
     `maven-publish`
+    signing
 }
 
 java {
@@ -112,47 +118,79 @@ protobuf {
 // Run "./gradlew publishReleasePublicationToLocalRepository" to generate release JARs locally
 publishing {
     publications {
+        val mavenGroupId = "net.newpipe"
+        val mavenArtifactId = "extractor"
+        fun MavenPublication.setupPOM() = pom {
+            name = "NewPipe Extractor"
+            description = "A library for extracting data from streaming websites, used in NewPipe"
+            url = "https://github.com/TeamNewPipe/NewPipeExtractor"
+
+            licenses {
+                license {
+                    name = "GNU GENERAL PUBLIC LICENSE, Version 3"
+                    url = "https://www.gnu.org/licenses/gpl-3.0.txt"
+                }
+            }
+
+            scm {
+                url = "https://github.com/TeamNewPipe/NewPipeExtractor"
+                connection = "scm:git:git@github.com:TeamNewPipe/NewPipeExtractor.git"
+                developerConnection = "scm:git:git@github.com:TeamNewPipe/NewPipeExtractor.git"
+            }
+
+            developers {
+                developer {
+                    id = "newpipe"
+                    name = "Team NewPipe"
+                    email = "team@newpipe.net"
+                }
+            }
+        }
+
         create<MavenPublication>("release") {
-            groupId = "net.newpipe"
-            artifactId = "extractor"
+            groupId = mavenGroupId
+            artifactId = mavenArtifactId
             version = rootProject.version.toString()
 
             afterEvaluate {
                 from(components["java"])
             }
 
-            pom {
-                name = "NewPipe Extractor"
-                description = "A library for extracting data from streaming websites, used in NewPipe"
-                url = "https://github.com/TeamNewPipe/NewPipeExtractor"
-
-                licenses {
-                    license {
-                        name = "GNU GENERAL PUBLIC LICENSE, Version 3"
-                        url = "https://www.gnu.org/licenses/gpl-3.0.txt"
-                    }
-                }
-
-                scm {
-                    url = "https://github.com/TeamNewPipe/NewPipeExtractor"
-                    connection = "scm:git:git@github.com:TeamNewPipe/NewPipeExtractor.git"
-                    developerConnection = "scm:git:git@github.com:TeamNewPipe/NewPipeExtractor.git"
-                }
+            setupPOM()
+        }
+        create<MavenPublication>("snapshot") {
+            groupId = mavenGroupId
+            artifactId = mavenArtifactId
+            version = "${rootProject.version}-SNAPSHOT"
 
-                developers {
-                    developer {
-                        id = "newpipe"
-                        name = "Team NewPipe"
-                        email = "team@newpipe.net"
-                    }
-                }
+            afterEvaluate {
+                from(components["java"])
             }
+
+            setupPOM()
         }
         repositories {
+            maven {
+                name = "sonatype"
+                url = uri("https://s01.oss.sonatype.org/content/repositories/snapshots/")
+                credentials {
+                    username = System.getenv("SONATYPE_MAVEN_CENTRAL_USERNAME")
+                    password = System.getenv("SONATYPE_MAVEN_CENTRAL_PASSWORD")
+                }
+            }
             maven {
                 name = "local"
                 url = uri(layout.buildDirectory.dir("maven"))
             }
         }
     }
 }
+
+signing {
+    useInMemoryPgpKeys(ciSigningKey, ciSigningPassword)
+    sign(publishing.publications["snapshot"])
+}
+
+tasks.withType<Sign> {
+    onlyIf("Signing credentials are present (only used for maven central)") { shouldSignRelease }
+}