Refactor and reconfigure publishing information for extractor

* Add missing information in pom file
* Add a new local maven repo to access the file easily
* Relocate the publishing instructions to extractor module
* Use the existing Gradle task to generate javadoc

Signed-off-by: Aayush Gupta <aayushgupta219@gmail.com>

Author: theimpulson

build.gradle.kts

@@ -12,7 +12,6 @@ plugins {
 
 allprojects {
     apply(plugin = "java-library")
-    apply(plugin = "maven-publish")
 
     tasks.withType<JavaCompile> {
         options.encoding = Charsets.UTF_8.toString()
@@ -22,25 +21,12 @@ allprojects {
         toolchain {
             languageVersion.set(JavaLanguageVersion.of(11))
         }
-        withSourcesJar()
-    }
-
-    version = "v0.24.8"
-    group = "com.github.TeamNewPipe"
-
-    afterEvaluate {
-        extensions.configure<PublishingExtension>("publishing") {
-            publications {
-                create<MavenPublication>("mavenJava") {
-                    from(components["java"])
-                }
-            }
-        }
     }
 }
 
 subprojects {
-    // Javadoc setup
+    // https://discuss.gradle.org/t/best-approach-gradle-multi-module-project-generate-just-one-global-javadoc/18657/21
+    // Fixes unknown tag @implNote; the other two were added precautionary
     tasks.withType<Javadoc>().configureEach {
         (options as StandardJavadocDocletOptions).apply {
             encoding = Charsets.UTF_8.toString()
@@ -53,12 +39,6 @@ subprojects {
         }
     }
 
-    // Prevent .proto files ending up in JARs
-    tasks.withType<Jar>().configureEach {
-        exclude("**/*.proto")
-        includeEmptyDirs = false
-    }
-
     // Test logging setup
     tasks.withType<Test>().configureEach {
         testLogging {
@@ -68,18 +48,3 @@ subprojects {
         }
     }
 }
-
-// https://discuss.gradle.org/t/best-approach-gradle-multi-module-project-generate-just-one-global-javadoc/18657/21
-tasks.register<Javadoc>("aggregatedJavadocs") {
-    title = "${project.name} ${project.version}"
-    setDestinationDir(layout.buildDirectory.dir("docs/javadoc").get().asFile)
-
-    subprojects.forEach { subProject ->
-        subProject.tasks.withType<Javadoc>().forEach { javadocTask ->
-            source = javadocTask.source
-            classpath += javadocTask.classpath
-            excludes += javadocTask.excludes
-            includes += javadocTask.includes
-        }
-    }
-}

extractor/build.gradle.kts

@@ -6,10 +6,23 @@
 plugins {
     alias(libs.plugins.google.protobuf)
     checkstyle
+    `maven-publish`
+}
+
+java {
+    withSourcesJar()
+    withJavadocJar()
+}
+
+// Protobuf files would uselessly end up in the JAR otherwise, see
+// https://github.com/google/protobuf-gradle-plugin/issues/390
+tasks.jar {
+    exclude("**/*.proto")
+    includeEmptyDirs = false
 }
 
 tasks.test {
-    // Pass on downloader type to tests for different CI jobs.
+    // Pass on downloader type to tests for different CI jobs. See DownloaderFactory.java and ci.yml
     if (System.getProperties().containsKey("downloader")) {
         systemProperty("downloader", System.getProperty("downloader"))
     }
@@ -71,3 +84,51 @@ protobuf {
         }
     }
 }
+
+// Run "./gradlew publishReleasePublicationToLocalRepository" to generate release JARs locally
+publishing {
+    publications {
+        create<MavenPublication>("release") {
+            groupId = "net.newpipe"
+            artifactId = "extractor"
+            version = "v0.24.8"
+
+            afterEvaluate {
+                from(components["java"])
+            }
+
+            pom {
+                name = "NewPipe Extractor"
+                description = "A library for extracting data from streaming websites, used in NewPipe"
+                url = "https://github.com/TeamNewPipe/NewPipeExtractor"
+
+                licenses {
+                    license {
+                        name = "GNU GENERAL PUBLIC LICENSE, Version 3"
+                        url = "https://www.gnu.org/licenses/gpl-3.0.txt"
+                    }
+                }
+
+                scm {
+                    url = "https://github.com/TeamNewPipe/NewPipeExtractor"
+                    connection = "scm:git:git@github.com:TeamNewPipe/NewPipeExtractor.git"
+                    developerConnection = "scm:git:git@github.com:TeamNewPipe/NewPipeExtractor.git"
+                }
+
+                developers {
+                    developer {
+                        id = "newpipe"
+                        name = "Team NewPipe"
+                        email = "team@newpipe.net"
+                    }
+                }
+            }
+        }
+        repositories {
+            maven {
+                name = "local"
+                url = uri(layout.buildDirectory.dir("maven"))
+            }
+        }
+    }
+}